Triple Repeat System v2

Contenuto del file

system "Triple Repeat System v2"
{
*************************************
*          System by KREV           *
*         on the VIP Lounge         *
*************************************
         Rx-ed by Sp1N-D1zZy
-------------------------------------
          not 00-c0mpatible
-------------------------------------
1) play each session up to a max of 37 spins.
2) do not place any bet at the start - just observe for a number to appear
three times.
3) when a number repeats 3x start to place a unit bet on that number on
every spin thereafter (the first bet will happen somewhere in the middle
to the end of the 37 spins cycle).
4) you also bet 1 unit on any other other repeated x3 numbers that appear.
5) the session will come to an end when:
-- you reached the max spin of 37 spins
6) play one session after another. in other words when one session ends
another session resets on the very next spin.
We bet just enough to be in profit.
-------------------------------------
}
method "main"
begin
while starting new session
    begin
    load single wheel
    call "Init"
    exit
    end
track last number for 37 spins record"Last 37"layout
add 1 record"Master Count"data
if flag "Bet" true
    begin
    call "Bet"
    end
call "Track"
end

method "Bet"
begin
if record"Master Count"data = 37
    begin
    set flag "Bet" false
    put 0 record"Master Count"data
    clear record"Bet this"layout
    clear record"Last 37"layout
    exit
    end
call "Calc Unit"
put 100% record"Unit Size"data record"Bet this"layout list
end

method "Calc Unit"
begin
if bankroll >= record"Starting Bankroll"data
    begin
    put 1 record"Unit Size"data
    put 100% bankroll record"Starting Bankroll"data
    end else begin
    put 100% record"Starting Bankroll"data record"Loss"data
    subtract 100% bankroll record"Loss"data
    put 37 record"Win Amount"data
    subtract 100% record"Bet this"layout index record"Win amount"data
    put 0 record"Temp"data
    put 0 record"Unit Size"data
    loop until record"Temp"data >= record"Loss"data
        begin
        add 1 record"Unit Size"data
        add 100% record"Win amount"data record"Temp"data
        end
    end
end

method "Track"
begin
if record"Master Count"data = 37
    begin
    set flag "Bet" false
    put 0 record"Master Count"data
    clear record"Bet this"layout
    clear record"Last 37"layout
    exit
    end
if record"Last 37"layout count > 0
    begin
    clear record"Number Count"data
    put 1 record"Single Wheel"layout index
    put 1 record"Last 37"layout index
    put 1 record"Number Count"data index
    loop until record"Single Wheel"layout index > record"Single Wheel"layout count
        begin
        loop until record"Last 37"layout index > record"Last 37"layout count
            begin
            if record"Last 37"layout = record"Single Wheel"layout
                begin
                add 1 record"Number Count"data
                end
            add 1 record"Last 37"layout index
            end
        put 1 record"Last 37"layout index
        add 1 record"Single Wheel"layout index
        add 1 record"Number Count"data index
        end
    end
put 1 record"Number Count"data index
put 1 record"Single Wheel"layout index
loop until record"Number Count"data index > record"Number Count"data count
    begin
    if record"Number Count"data = 3
        begin
        if record"Single Wheel"layout found record"Bet this"layout
            begin end else begin
            copy record"Single Wheel"layout record"Bet this"layout
            add 1 record"Bet this"layout index
            end
        set flag "Bet" true
        end
    add 1 record"Number count"data index
    add 1 record"Single Wheel"layout index
    end
if flag "Bet" true
    begin
    call "Bet"
    end
end

method "Init"
begin
copy list [0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,
27,28,29,30,31,32,33,34,35,36] record"Single Wheel"layout
put 100% bankroll record"Starting Bankroll"data
end