The Da Vinci Code v2

Contenuto del file

system "The Da Vinci Code v2"
{
*************************************
*        System by Turbogenius      *
*         on the VIP Lounge         *
*************************************
          Rx-ed by St0rm0r
-------------------------------------
           00-c0mpatible
-------------------------------------
Play 1 dozen or column only
Record 37 spins.

If you have more than 3 sleepers in your chosen dozen, flat bet them (the sleepers) for the next 37 spins.
If you have less than 4 sleepers (3 or less) then requalify - run off another 37 spins from scratch.

Don't remove winners or do anything other than repeating your bets for all 37 spins.

While doing this, record for your next session so you can pick up with the new bets once you're done.
-------------------------------------
}
method "main"
begin
// section 1: do this once
while starting new session
    begin
    call "init"
    exit
    end

// section 2: do the tracking
if record"play"data = 2
    begin
    if bankroll > record"high"data
        begin
        //clear record"last 37"layout
        set flag "qualified" false
        put 100% bankroll record"high"data
        end
    end

track last number for record"amount"data times record"last 37"layout
if record"last 37"layout count < record"amount"data
    begin exit end

// section 3:act when not qualified
if flag "qualified" false
    begin
    call "get number of sleepers"
    call "check for qualification"
    put 0 record"#bets"data
    if flag "qualified" false
        begin clear record"last 37"layout end
    end

// section 4:act when  qualified
if flag "qualified" true
    begin
    //bet
    if flag "1st" true
        begin put 1 record"play 1st"layout list
        multiply by 100% record"base bet"data record"play 1st"layout list end
    if flag "2nd" true
        begin put 1 record"play 2nd"layout list
        multiply by 100% record"base bet"data record"play 2nd"layout list end
    if flag "3rd" true
        begin put 1 record"play 3rd"layout list
        multiply by 100% record"base bet"data record"play 3rd"layout list end
    if flag "A" true
        begin put 1 record"play A"layout list
        multiply by 100% record"base bet"data record"play A"layout list end
    if flag "B" true
        begin put 1 record"play B"layout list
        multiply by 100% record"base bet"data record"play B"layout list end
    if flag "C" true
        begin put 1 record"play C"layout list
        multiply by 100% record"base bet"data record"play C"layout list end
    add 1 record"#bets"data
    if record"#bets"data = record"amount"data
        begin set flag "qualified" false end
    end
end

// subroutines
method "init"
begin
group
    begin
    display "The Da Vinci Code v1"
    display "----------------------------------------"
    input checkbox "Play 1st dozen" flag "1st"
    input checkbox "Play 2nd dozen" flag "2nd"
    input checkbox "Play 3rd dozen" flag "3rd"
    input checkbox "Play column A" flag "A"
    input checkbox "Play column B" flag "B"
    input checkbox "Play column C" flag "C"
    input checkbox "Play the dozen or column with the most sleepers" flag "X"
    display "----------------------------------------"
    input data "Base bet" record"base bet"data
    input dropdown "Wheel:
    1:= single
    2:= double" record"wheel"data
    input dropdown "Play
    1:= always 37 spins
    2:= until in profit but not more then 37 spins" record"play"data
    input data "Bet only if there are minimum X number of sleepers" record"X sleepers"data
    display "AND"
    input data "Bet only if there are maximum Y number of sleepers" record"Y sleepers"data
    end
if record"wheel"data = 1
    begin
    load single wheel
    put 37 record"amount"data
    end
    else
    begin
    load double wheel
    put 38 record"amount"data
    end
copy list [number 1,number 2,number 3,number 4,number 5,number 6,number 7,
number 8,number 9,number 10,number 11,number 12] to record"1st dozen"layout
copy list [number 13,number 14,number 15,number 16,number 17,number 18,number 19,
number 20,number 21,number 22,number 23,number 24] to record"2nd dozen"layout
copy list [number 25,number 26,number 27,number 28,number 29,number 30,
number 31,number 32,number 33,number 34,number 35,number 36] to record"3rd dozen"layout
copy list [number 1,number 4,number 7,number 10,number 13,number 16,
number 19,number 22,number 25,number 28,number 31,number 34] to record"column A"layout
copy list [number 2,number 5,number 8,number 11,number 14,number 17,
number 20,number 23,number 26,number 29,number 32,number 35] to record"column B"layout
copy list [number 3,number 6,number 9,number 12,number 15,number 18,
number 21,number 24,number 27,number 30,number 33,number 36] to record"column C"layout
set flag "qualified" false
put 100% bankroll record"high"data
end

method "get number of sleepers"
begin
put 0 record"temp"data
put 0 record"most sleepers"data
clear record"play 1st"layout
put 1 record"play 1st"layout index
put 1 record"1st dozen"layout index
loop until record"1st dozen"layout index > record"1st dozen"layout count
    begin
    if record"1st dozen"layout is not found in record"last 37"layout
        begin
        copy record"1st dozen"layout record"play 1st"layout
        add 1 record"play 1st"layout index
        end
    add 1 record"1st dozen"layout index
    end
if record"play 1st"layout index > record"temp"data
    begin
    put 100% record"play 1st"layout index record"temp"data
    put 1 record"most sleepers"data
    end

clear record"play 2nd"layout
put 1 record"play 2nd"layout index
put 1 record"2nd dozen"layout index
loop until record"2nd dozen"layout index > record"2nd dozen"layout count
    begin
    if record"2nd dozen"layout is not found in record"last 37"layout
        begin
        copy record"2nd dozen"layout record"play 2nd"layout
        add 1 record"play 2nd"layout index
        end
    add 1 record"2nd dozen"layout index
    end
if record"play 2nd"layout index > record"temp"data
    begin
    put 100% record"play 2nd"layout index record"temp"data
    put 2 record"most sleepers"data
    end

clear record"play 3rd"layout
put 1 record"play 3rd"layout index
put 1 record"3rd dozen"layout index
loop until record"3rd dozen"layout index > record"3rd dozen"layout count
    begin
    if record"3rd dozen"layout is not found in record"last 37"layout
        begin
        copy record"3rd dozen"layout record"play 3rd"layout
        add 1 record"play 3rd"layout index
        end
    add 1 record"3rd dozen"layout index
    end
if record"play 3rd"layout index > record"temp"data
    begin
    put 100% record"play 3rd"layout index record"temp"data
    put 3 record"most sleepers"data
    end

clear record"play A"layout
put 1 record"play A"layout index
put 1 record"column A"layout index
loop until record"column A"layout index > record"column A"layout count
    begin
    if record"column A"layout is not found in record"last 37"layout
        begin
        copy record"column A"layout record"play A"layout
        add 1 record"play A"layout index
        end
    add 1 record"column A"layout index
    end
if record"play A"layout index > record"temp"data
    begin
    put 100% record"play A"layout index record"temp"data
    put 4 record"most sleepers"data
    end

clear record"play B"layout
put 1 record"play B"layout index
put 1 record"column B"layout index
loop until record"column B"layout index > record"column B"layout count
    begin
    if record"column B"layout is not found in record"last 37"layout
        begin
        copy record"column B"layout record"play B"layout
        add 1 record"play B"layout index
        end
    add 1 record"column B"layout index
    end
if record"play B"layout index > record"temp"data
    begin
    put 100% record"play B"layout index record"temp"data
    put 5 record"most sleepers"data
    end

clear record"play C"layout
put 1 record"play C"layout index
put 1 record"column C"layout index
loop until record"column C"layout index > record"column C"layout count
    begin
    if record"column C"layout is not found in record"last 37"layout
        begin
        copy record"column C"layout record"play C"layout
        add 1 record"play C"layout index
        end
    add 1 record"column C"layout index
    end
if record"play C"layout index > record"temp"data
    begin
    put 100% record"play C"layout index record"temp"data
    put 6 record"most sleepers"data
    end
end

method "check for qualification"
begin
if flag "X" true
    begin
    set flag "1st" false
    set flag "2nd" false
    set flag "3rd" false
    set flag "A" false
    set flag "B" false
    set flag "C" false
    if record"most sleepers"data = 1
        begin set flag "1st" true end
    if record"most sleepers"data = 2
        begin set flag "2nd" true end
    if record"most sleepers"data = 3
        begin set flag "3rd" true end
    if record"most sleepers"data = 4
        begin set flag "A" true end
    if record"most sleepers"data = 5
        begin set flag "B" true end
    if record"most sleepers"data = 6
        begin set flag "C" true end
    end

if flag "1st" true
    begin
    if record"play 1st"layout count >= record"X sleepers"data and  record"play 1st"layout count <= record"Y sleepers"data
        begin set flag "qualified" true end
    end
if flag "2nd" true
    begin
    if record"play 2nd"layout count >= record"X sleepers"data and  record"play 2nd"layout count <= record"Y sleepers"data
        begin set flag "qualified" true end
    end
if flag "3rd" true
    begin
    if record"play 3rd"layout count >= record"X sleepers"data and  record"play 3rd"layout count <= record"Y sleepers"data
        begin set flag "qualified" true end
    end
if flag "A" true
    begin
    if record"play A"layout count >= record"X sleepers"data and  record"play A"layout count <= record"Y sleepers"data
        begin set flag "qualified" true end
    end
if flag "B" true
    begin
    if record"play B"layout count >= record"X sleepers"data and  record"play B"layout count <= record"Y sleepers"data
        begin set flag "qualified" true end
    end
if flag "C" true
    begin
    if record"play C"layout count >= record"X sleepers"data and  record"play C"layout count <= record"Y sleepers"data
        begin set flag "qualified" true end
    end
end