Hot 18 v1

Contenuto del file

system "Hot 18 v1"
{
*************************************
*         System by geoff365        *
*         on the VIP Lounge         *
*************************************
          Rx-ed by St0rm0r
-------------------------------------
           00-c0mpatible
-------------------------------------
Back the 18 numbers that have arrived the most.
If 2 numbers have arrived the same amount of times back the number that arrived last.
-------------------------------------
}
method "main"
begin
// section 1: do this once
while starting new session
    begin
    call "init"
    exit
    end

// section 2: do the tracking
track last number for 1 record"last N"layout
put 1 record"numbers"layout index
loop until record"numbers"layout = record"last N"layout
    begin
    add 1 record"numbers"layout index
    end
put 100% record"numbers"layout index record"hit"data index
put 100% record"hit"data record"how many hits"data
add 1 record"how many hits"data

set flag "put away" false
clear record"temp1"layout
put 1 record"temp1"layout index
clear record"temp2"data
put 1 record"temp2"data index
put 1 record"numbers"layout index
loop until record"numbers"layout index > record"numbers"layout count
    begin
    put 100% record"numbers"layout index record"hit"data index
    if record"hit"data < record"how many hits"data or flag "put away" true
        begin
        if record"numbers"layout not = record"last N"layout
            begin
            copy record"numbers"layout record"temp1"layout
            add 1 record"temp1"layout index
            put 100% record"hit"data record"temp2"data
            add 1 record"temp2"data index
            end
        end
        else
        begin
        if flag "put away" false
            begin
            copy record"last N"layout record"temp1"layout
            add 1 record"temp1"layout index
            copy record"numbers"layout record"temp1"layout
            add 1 record"temp1"layout index
            put 100% record"how many hits"data record"temp2"data
            add 1 record"temp2"data index
            put 100% record"hit"data record"temp2"data
            add 1 record"temp2"data index
            set flag "put away" true
            end
        end
    add 1 record"numbers"layout index
    end
if flag "put away" false
    begin
    copy record"last N"layout record"temp1"layout
    put 100% record"how many hits"data record"temp2"data
    end
duplicate record"temp1" record"numbers"
duplicate record"temp2" record"hit"

// section 3: act on a loss
if net < 0
    begin

    end

// section 4:act on a win
if net > 0
    begin
    set flag "qualified" false
    end

//section 5: act when not qualified
if flag "qualified" false
    begin
    clear record"play"layout
    put 38 record"hit"data index
    loop until record"hit"data index = 20
        begin
        put 100% record"hit"data index record"numbers"layout index
        if record"hit"data > 0
            begin
            copy record"numbers"layout record"play"layout
            add 1 record"play"layout index
            end
        subtract 1 record"hit"data index
        end
    if record"play"layout count = 18
        begin
        set flag "qualified" true
        end
    end

//section 6: act when qualified
if flag "qualified" true
    begin
    //bet
    put 1 record"play"layout list
    end
if record"P"data = 2
    begin
    set flag "qualified" false
    end
end

// subroutines
method "init"
begin
group
    begin
    display "Hot 18"
    display "-----------------------------------------------------------------"
    input dropdown "Keep the hot 18
    1:= the same until a win
    2:= variable; playing the hottest 18 each time" record"P"data
    end
copy list [number 00, number 0, number 1, number 2, number 3,number 4,number 5,number 6,
number 7,number 8,number 9,number 10,number 11,number 12,number 13,number 14,
number 15,number 16,number 17,number 18,number 19,number 20,number 21,number 22,
number 23,number 24,number 25,number 26,number 27,number 28,number 29,number 30,
number 31,number 32,number 33,number 34,number 35,number 36] to record"numbers"layout
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] record"hit"data
call "reset"
end

method "reset"
begin
set flag "qualified" false
end