Holy Grail Formula

Contenuto del file

system "Apache's HGF v1"
{
*************************************
*        System by Apache           *
*       on the VIP Lounge           *
*************************************
        Rx-ed by St0rm0r

-------------------------------------
            00-c0mpatible
-------------------------------------
HGF = Holy Grail Formula
HGF = (#shows)/#spins*#spins sleeping
Example :
Number 1 hit 19 times in last 660 spins and sleeps 122 spins
HGF number 1 = 19/660*122 = 3,52
-------------------------------------
}
method "main"
begin
// section 1: do this once
while starting new session
    begin
    call "init"
    exit
    end

// section 2: do the tracking
track last number for 1 time record"last#"layout
//update statistics
call "update statistics"
//update parameters
add 1 record"#spins"data
call "update frequencies"
call "calculate GHFs"

// section 3: act on a loss
if net < 0
    begin
    subtract 100% net record"loss"data
    end

// section 3: act on a loss
if net > 0
    begin
    subtract 100% net record"loss"data
    if record"loss"data < 0
        begin
        put 0 record"loss"data
        end
    end

//bet
if record"P"data = 1
    begin
    put 1 record"unit"data
    end
    else
    begin
    call"calculate unit"
    end
put 1 record"HGF"data index
loop until record"HGF"data index > record"HGF"data count
    begin
    if record"HGF"data > record"low"data and record"HGF"data < record"high"data
        begin
        put 100% record"HGF"data index record"numbers"layout index
        put 100% of record"unit"data record"numbers"layout
        end
    add 1 record"HGF"data index
    end

end

// subroutines
method "init"
begin
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] record"HGF"data
clear record"HGF x 10 frequency"data
group
    begin
    display "Apache's HGF v1"
    display "---------------------------"
    display "Bet numbers with 100*HGF"
    input data "higher then: (e.g.50) " record"low"data
    display "and"
    input data "lower then: (e.g.400) " record"high"data
    input dropdown "Progression:
    1:= flat bet
    2:= enough to be positive in one bet" record"P"data
    end
put 1% record"low"data record"low"data
put 1% record"high"data record"high"data
copy list [number 00,number 0,number 1,number 2,number 3,number 4,number 5,number 6,
number 7,number 8,number 9,number 10,number 11,number 12,number 13,number 14,
number 15,number 16,number 17,number 18,number 19,number 20,number 21,number 22,
number 23,number 24,number 25,number 26,number 27,number 28,number 29,number 30,
number 31,number 32,number 33,number 34,number 35,number 36] to record"numbers"layout
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] record"hit"data
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] record"sleeping"data
put 0 record"#spins"data
call "reset"
end

method "reset"
begin
put 0 record"loss"data
end

method "update frequencies"
begin
put 1 record"numbers"layout index
loop until record"numbers"layout index > record"numbers"layout count
    begin
    put 100% record"numbers"layout index record"sleeping"data index
    if record"numbers"layout = record"last#"layout
        begin
        put 100% record"numbers"layout index record"hit"data index
        add 1 record"hit"data
        put 0 record"sleeping"data
        end
        else
        begin
        add 1 record"sleeping"data
        end
    add 1 record"numbers"layout index
    end
end

method "calculate GHFs"
begin
put 1 record"hit"data index
loop until record"hit"data index > record"hit"data count
    begin
    put 100% record"hit"data index record"sleeping"data index
    put 100% record"hit"data index record"HGF"data index
    put 100% record"hit"data record"HGF"data
    divide by 100% record"#spins"data on record"HGF"data
    multiply by 100% record"sleeping"data record"HGF"data
    add 1 record"hit"data index
    end
end

method "update statistics"
begin
put 1 record"numbers"layout index
loop until record"numbers"layout = record"last#"layout
    begin
    add 1 record"numbers"layout index
    end
put 100% record"numbers"layout index record"HGF"data index
put 1000% record"HGF"data red
put 100% red on record"HGF x 10 frequency"data index
add 1 record"HGF x 10 frequency"data
put 0 red
end

method"calculate unit"
begin
put 0 record"# of numbers"data
put 1 record"HGF"data index
loop until record"HGF"data index > record"HGF"data count
    begin
    if record"HGF"data > record"low"data and record"HGF"data < record"high"data
        begin
        add 1 record"# of numbers"data
        end
    add 1 record"HGF"data index
    end
put 0 record"unit"data
loop until record"ref"data < 0
    begin
    add 1 record"unit"data
    put 100% record"loss"data in record"ref"data
    put 100% record"unit"data record"temp"data
    multiply by 100% record"# of numbers"data record"temp"data
    add 100% record"temp"data record"ref"data
    put 36 record"temp"data
    multiply by 100% record"unit"data record"temp"data
    subtract 100% record"temp"data record"ref"data
    end
put 0 record"ref"data
end