Double Streets

Contenuto del file

system "Lohnro Double Streets"
{
*************************************
*         System by Lohnro          *
*         on the VIP Lounge         *
*************************************
         Rx-ed by Sp1N-D1zZy
-------------------------------------
           00-c0mpatible
-------------------------------------
Track last 12 double streets. If one streets and only one street
has show 4 or more times, bet until a win with the following progression:

1,1,2,2,3,3,4,4,5,6
-------------------------------------
}
method "main"
begin
while starting new session
    begin
    call "Init"
    end
call "Track"
if flag "Bet" true
    begin
    call "Place bets"
    end
    else
    begin
    call "Get number"
    end
end

method "Place Bets"
begin
put 100% record"Progression"data record"Bet this"layout
if record"Progression"data index > record"Progression"data count
or net > 0
    begin
    set flag "Bet" false
    put 0 record"Progression"data index
    put 0 all bets
    end
add 1 record"Progression"data index
end

method "Get number"
begin
if record"Last 12 streets"layout count = 12
    begin
    clear record"Get number"data
    put 1 record"Get number"data index
    put 1 record"Street master"layout index
    put 1 record"Last 12 streets"layout index
    loop until record "Street master"layout index > record"Street master"layout count
        begin
        loop until record"Last 12 streets"layout index = 13
            begin
            if record"Last 12 streets"layout = record"Street master"layout
                begin
                add 1 record"Get number"data
                end
            add 1 record"Last 12 streets"layout index
            end
        add 1 record"Get number"data index
        add 1 record"Street master"layout index
        put 1 record"Last 12 streets"layout index
        end
    put 12 record"Last 12 streets"layout index
    put 1 record"Get number"data index
    put 1 record"Street master"layout index
    put 0 record"# Qualified DStreets"data
    loop until record"Get number"data index > record"Get number"data count
        begin
        if record"Get number"data >= 4
            begin
            add 1 record"# Qualified DStreets"data
            copy record"Street master"layout record"Bet this"layout
            end
        add 1 record"Get number"data index
        add 1 record"Street master"layout index
        end
    if record"# Qualified DStreets"data = 1
        begin
        set flag "Bet" true
        call "Place bets"
        end
    end
end

method "Track"
begin
put 1 record"Street Layout"layout index
put 1 record"Number Layout"layout index
if record"Last 12 streets"layout count = 12
    begin
    if number 0 hit each or number 00 hit each
        begin end else begin
        move list up 1 record"Last 12 streets"layout
        end
    end
loop until flag "Stop" true
    begin
    if number 0 hit each or number 00 hit each
        begin
        if flag "Bet" true
            begin
            call "Place Bets"
            end
        exit
        end
   if record"Number Layout"layout hit each
        begin
        copy record"Street Layout"layout record"Last 12 streets"layout
        if record"Last 12 streets"layout count < 12
            begin
            add 1 record"Last 12 streets"layout index
            end
        set flag "Stop" true
        end
    add 1 record"Street Layout"layout index
    add 1 record"Number Layout"layout index
    end
set flag "Stop" false
end

method "Init"
begin
copy list [line(1-6),line(1-6),line(1-6),line(1-6),line(1-6),line(1-6),
line(7-12),line(7-12),line(7-12),line(7-12),line(7-12),line(7-12),
line(13-18),line(13-18),line(13-18),line(13-18),line(13-18),line(13-18),
line(19-24),line(19-24),line(19-24),line(19-24),line(19-24),line(19-24),
line(25-30),line(25-30),line(25-30),line(25-30),line(25-30),line(25-30),
line(31-36),line(31-36),line(31-36),line(31-36),line(31-36),line(31-36)]
record"Street Layout"layout
copy list [line(1-6), line(7-12), line(13-18), line(19-24), line(25-30), line(31-36)]
record"Street Master"layout
set list [0,0,0,0,0,0] record"Get number"data
copy list [1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,
26,27,28,29,30,31,32,33,34,35,36] record"Number Layout"layout
put 0 record"Last 12 streets"layout index
set list [1,1,2,2,3,3,4,4,5,6] record"Progression"data
exit
end