Lappa Three v2

Contenuto del file

system "Lappa Three v2"
{
*************************************
*        System by Lappa            *
*       on the VIP Lounge           *
*************************************
        Rx-ed by St0rm0r

Spin 1, bet number 1. Spin 2, bet number 2 and so on.
Bet this system flat.
On a win, start at number 1 again.
Meantime, track the dozens.
Wait for dozen 1 or dozen 3 to hit 3 times in a row.
When 3rd dozen hit 3 times in a row, bet maximum 2 times on dozen 2.
When 1st dozen hit 3 times in a row, bet maximum 2 times on dozen 3.
Flat bet or use progression
1-1-2-3-4-5-8-11-18.
}
method "main"
begin
while starting new session
    begin
    call "init"
    end

add 1 record"#bets"data
add 1 record"spin#"data

track last dozen for 1 time record"last dozen"layout

if any number bet won each
    begin
    put 1 record"spin#"data
    end
if any number bet lost each
    begin
    if record"spin#"data > 36
        begin
        put 1 record"spin#"data
        end
    end

if any dozen bet lost each
    begin
    add 1 record"pro"data index
    if record"pro"data index > record"pro"data count
        begin
        put 1 record"pro"data index
        end
    if record"#bets"data = 2
        begin
        call"reset"
        end
    end

if any dozen bet won each
    begin
    put 1 record"pro"data index
    call"reset"
    end

if flag "qualified" false
    begin
    if record"last dozen"layout = 1st dozen
        begin
        add 1 record"1st dozen"data
        if record"1st dozen"data = 3
            begin
            copy 3rd dozen to record"bet on"layout
            put 0 record"#bets"data
            set flag "qualified" true
            end
        put 0 record"3rd dozen"data
        end
     if record"last dozen"layout = 2nd dozen
        begin
        put 0 record"1st dozen"data
        put 0 record"3rd dozen"data
        end
    if record"last dozen"layout = 3rd dozen
        begin
        add 1 record"3rd dozen"data
        if record"3rd dozen"data = 3
            begin
            copy 2nd dozen to record"bet on"layout
            put 0 record"#bets"data
            set flag "qualified" true
            end
        put 0 record"1st dozen"data
        end
    end

if flag "qualified" true
    begin
    put 100% record"pro"data on record"bet on"layout
    multiply by 100% of record"unit"data on record"bet on"layout
    end

put 100% record"spin#"data on record"numbers"layout index
put 100% of record"unit"data on record"numbers"layout
end

method "init"
begin
put 0 record"spin#"data
copy list [number 1, number 2, number 3,number 4,number 5,number 6,
number 7,number 8,number 9,number 10,number 11,number 12,number 13,number 14,
number 15,number 16,number 17,number 18,number 19,number 20,number 21,number 22,
number 23,number 24,number 25,number 26,number 27,number 28,number 29,number 30,
number 31,number 32,number 33,number 34,number 35,number 36] to record"numbers"layout
group
    begin
    display "LAPPA THREE v2 SYSTEM"
    input dropdown "Use progression:
    1:= flat bet
    2:= 1-1-2-3-4-5-8-11-18-31 " to record"progression"data
    input data "unit size" to record"unit"data
    end
if record"progression"data = 1
    begin
    set list [1] to record"pro"data
    end
    else
    begin
    set list [1,1,2,3,4,5,8,11,18] to record"pro"data
    end
put 1 record"pro"data index
call "reset"
end

method "reset"
begin
set flag "qualified" false
put 0 record"1st dozen"data
put 0 record"3rd dozen"data
end