Simple system

Contenuto del file

system "Gerhard_Simple_system"

{ The rules;
1) You can bet on any even chance.
2) You will always begin a game with this progression- (1,0)
3) Any lost "LOW" bet is added to the beginning
4) Any lost "HIGH" bet is added to the end
5) Any lost bet is immediately followed by a "LOW" bet
6) Any won bet is immediately followed by a "HIGH" bet
7) Any "LOW" bet lost is added to the beginning of the progression
8) Any "HIGH" bet lost is added to the end of the progression
9) You will ignore the zero in the progression when betting, its only a visual

aid
10) Any number to the left of the "0" is treated as one sum, i.e. (1,1,1,1,0,1)

is (4,0,1)
I think I covered all the bases so I will continue with an example:
In this example I will be betting on "RED". The example will unfold as

follows;
The first figure is the spin number, i.e. 1,2,3,4,5, etc.
The second figure is the hit number, i.e. 25,36,3,0,12, etc.
The third figure is the bet decision, i.e. "LOW" or "HIGH"
The fourth figure is that spins balance
The fifth figure is the net balance since session started
The sixth is a reference to the progression so you won't get lost
11)Treat each new session as a high bet. Example: Your first bet loses so your

progression would look like this (1.0.1).
12)Reset progression after last progression cancels out.

}
method "main"
begin
while Starting a new Session
begin
call "init"
end

if record "even money" layout has lost each time
begin
if flag "High Bet" is true
begin
set max to record "HIGH" data index
add 1 to record "HIGH" data index
put 100% of record "bet" data to record "HIGH" data
end
else
begin
call "Add lost bet to beginning"
end

set flag "High Bet" to false
end

if record "even money" layout has won each time
begin
if flag "High Bet" is true
begin
call "Remove from items from list"
end

set flag "High Bet" to true
end

if flag "High Bet" is true
begin
call "Do HIGH bet"
end
else
begin
put 1 unit to record "bet" data
put 100% of record "bet" data to record "even money" layout
end
end

//"HIGH" means a high bet which is the sum of the first and last numbers
//in the progression
method "Do HIGH bet"
begin
put 0 on record "bet" data
put 1 on record "LOW" data index

loop until record "LOW" data index > record "LOW" data count
begin
add 100% of record "LOW" data to record "bet" data
add 1 to record "LOW" data index
end

if record "bet" data = 0
begin
if record "HIGH" data count > 1
begin
put 1 on record "HIGH" data index
put 100% of record "HIGH" data to record "bet" data
end
end

set max to record "HIGH" data index
add 100% of record "HIGH" data to record "bet" data

if record "bet" data = 0
begin
put 1 on record "bet" data
end

put 100% of record "bet" data to record "even money" layout
end

//Any "LOW" bet lost is added to the beginning of the progression
method "Add lost bet to beginning"
begin
duplicate record "LOW" to record "temp"
clear record "LOW" data
put 1 on record "temp" data index
put 2 on record "LOW" data index

loop until record "temp" data index > record "temp" data count
begin
put 100% of record "temp" data to record "LOW" data
add 1 to record "temp" data index
add 1 to record "LOW" data index
end

put 1 to record "LOW" data index
put 100% of record "bet" data to record "LOW" data
end

//Won with HIGH bet placed. Remove HIGH and LOW from list
method "Remove from items from list"
begin
//remove last item in HIGH list
duplicate record "HIGH" to record "temp"
clear record "HIGH" data
set max to record "temp" data index
put 100% of record "temp" data index to record "max HIGH" data
subtract 1 from record "max HIGH" data

put 1 on record "temp" data index
put 1 on record "HIGH" data index

if record "LOW" data count = 0
begin
add 1 to record "temp" data index
end

loop until record "temp" data index > record "max HIGH" data
begin
put 100% of record "temp" data to record "HIGH" data
add 1 to record "temp" data index
add 1 to record "HIGH" data index
end

//remove all items in LOW list
clear record "LOW" data

if record "HIGH" data count = 0
begin
add 1 to record "session count" data
put 1 on record "LOW" data
clear record "HIGH" data
end
end

method "init"
begin
set flag "High Bet" to true
put 0 to record "session count" data
put 0 on record "bet" data
put 1 on record "LOW" data
clear record "HIGH" data

group
begin
Display "Gerhard's Simple System"
Input Dropdown "Make a Layout Selection

1:=Red
2:=Black
3:=Even
4:=Odd
5:=High (19-36)
6:=Low (1-18)" to
Record "Layout number" data
end

if record "Layout number" data = 1 then
begin
copy red to record "even money" layout
end

if record "Layout number" data = 2 then
begin
copy black to record "even money" layout
end

if record "Layout number" data = 3 then
begin
copy even to record "even money" layout
end

if record "Layout number" data = 4 then
begin
copy odd to record "even money" layout
end

if record "Layout number" data = 5 then
begin
copy high to record "even money" layout
end

if record "Layout number" data = 6 then
begin
copy low to record "even money" layout
end
end