Hot numbers

Contenuto del file

system "Geoff's Hot Numbers"
{
**************************
*   System by Geoff365   *
*   on the VIP Lounge    *
**************************
Tue May 17, 2005 9:09 pm
   Topic: Hot Numbers
    Rx-ed by St0rm0r

Method:
"Wait for 6 numbers to arrive in twice then flat bet on them
plus any more that arrive.
Stay on all the numbers to a max of 18 numbers
What is required is a 18 unit win."
}
method "main"
begin
while starting new session
    begin
    call "init"
    end

if bankroll <= record"stop loss"data
    begin
    call"reset"
    exit
    end

if bankroll >= record"reference bank"data
    begin
    call"reset"
    exit
    end

track last number for 1 time in record"last number"layout
call "update frequency list"


if flag "qualify" false
    begin
    if record"# of numbers arrived twice or more" data >=6
        begin
        set flag "qualify" true
        end
    end

if flag "qualify" true
    begin
    //bet maximum 18 numbers
    if record"# of numbers arrived twice or more" data =19
        begin
        call"reset"
        exit
        end
    //bet
    put 1 in record "layout list"layout index
    loop until record "layout list"layout index > record "layout list"layout count
        begin
        put 100% of record "layout list"layout index in record"frequency list"data index
        if record"frequency list"data > 1
            begin
            put 1 on record "layout list"layout
            end
        add 1 to record "layout list"layout index
        end
    end
end

method "init"
begin
copy list [number 0,number 1,number 2,number 3,number 4,number 5,number 6,
number 7,number 8,number 9,number 10,number 11,number 12,number 13,number 14,
number 15,number 16,number 17,number 18,number 19,number 20,number 21,number 22,
number 23,number 24,number 25,number 26,number 27,number 28,number 29,number 30,
number 31,number 32,number 33,number 34,number 35,number 36 ] to record "layout list"layout
call "reset"
end

method "reset"
begin
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
0,0,0] to record"frequency list"data
set flag "qualify" false
put 0 in record"# of numbers arrived twice or more" data
put 100% of bankroll in record"reference bank"data
// on an 18 unit win, start all over
add 18 to record"reference bank"data
put 100% of bankroll in record"stop loss"data
// here the stop loss units are set  (set now at 5000 LOL)
subtract 5000 from record"stop loss"data
end

method "update frequency list"
begin

put 1 in record "layout list"layout index
loop until record "layout list"layout index > record "layout list"layout count
    begin
    if record"last number"layout = record "layout list"layout
        begin
        put 100% of record "layout list"layout index in record"frequency list"data index
        add 1 to record"frequency list"data
        if record"frequency list"data = 2
            begin
            add 1 to record"# of numbers arrived twice or more" data
            end
        end
    add 1 to record "layout list"layout index
    end
end