11 sector

Contenuto del file

system "11 sector"
{
My method(Final):

1. Look at the last 3 spins, choose the number that has the lowest amount of
hits in it's 11 number section, where the number you choose is the center
number of the 11 number sector(moving sector). Which means 5 numbers to each
side of it, including itself. If there is the same number of lowest amount
of hits in a sector, simply choose the latest number, or alternately,
wait(do not bet) and continue progression when one is clearly the lowest.
2. Play these 11 numbers using the progression below.
3. Choose new numbers according to step 1 after every spin.
4. Advance in progression until a hit, in which case start the progression
over again. Start over at step #1. If no hit at the end of the progression,
start over at step #1.
5. Repeat step 1 after a hit or 7 progressions without a hit.
*Win +200 is stop.


Progressions:

1. Flat Bet

Spin Stake Profit Outlay
1 1 25 11
2 1 14 22
3 1 3 33
4 1 -8 44
5 1 -19 55
6 1 -30 66
7 1 -41 77



2. Ivor Style

Spin Stake Profit Outlay
1 4 100 44
2 5 81 99
3 6 51 165
4 8 35 253
5 11 22 374
6 15 1 539
7 21 -14 770



3. Even Profit

Spin Stake Profit Outlay
1 1 25 11
2 2 39 33
3 3 42 66
4 4 34 110
5 6 40 176
6 9 49 275
7 13 50 418
}
method "main"
begin
while starting a new session
begin
call "init"
call "reset"
call "input"
exit
end

if any number bet has won each time
begin
put 1 on record "progression" data index

if bankroll > record "win stop" data
begin
display "You have reached your Win Stop. Session will END."
stop Session
end
end
copy last number to record "last number" layout
call "update hits"

// I removed the logic to check for duplicate Number in the track list.
// if record "last number" layout is not found in record "track 3 numbers" layout
// begin

//Now it will track ALL Numbers regardless of duplicates
track last Number for 3 times to record "track 3 numbers" layout
// end

if record "track 3 numbers" layout count not = 3
begin
exit
end

put 1 on record "track 3 numbers" layout index;call "get neighbors"
duplicate Record "working sector" to record "sector 1"
put 2 on record "track 3 numbers" layout index;call "get neighbors"
duplicate Record "working sector" to record "sector 2"
put 3 on record "track 3 numbers" layout index;call "get neighbors"
duplicate Record "working sector" to record "sector 3"


//determine lowest hist
put 1 on record "hit list" data index
put 100% of record "sector 1" data to record "hit list" data
add 1 on record "hit list" data index
put 100% of record "sector 2" data to record "hit list" data
add 1 on record "hit list" data index
put 100% of record "sector 3" data to record "hit list" data

call "determine lowest hits"

if flag "lowest found" is true
begin
if record "sector # to use" data = 1
begin
put 100% of record "progression" data to record "sector 1" layout list
end

if record "sector # to use" data = 2
begin
put 100% of record "progression" data to record "sector 2" layout list
end

if record "sector # to use" data = 3
begin
put 100% of record "progression" data to record "sector 3" layout list
end

add 1 to record "progression" data index

if record "progression" data index > record "progression" data count
begin
put 1 on record "progression" data index
end
end
end

method "determine lowest hits"
begin
put 0 on record "sector # to use" data
put 9999999999999999 on record "lowest" data //make it highest as possible
put 1 on record "hit list" data index

loop until record "hit list" data index > record "hit list" data count
begin
if record "hit list" data <= record "lowest" data
begin
set flag "lowest found" is true
put 100% of record "hit list" data index to record "sector # to use" data

if record "hit list" data = record "lowest" data
and record "wait to bet" data = 2
begin
set flag "lowest found" is false
end

put 100% of record "hit list" data to record "lowest" data
end

add 1 to record "hit list" data index
end
end

{This method will loop through 5 spaces and retrieve all numbers
from the Right and Left of the Number that is in the Last 3 track record.

The end result is a record "working sector" with 10 numbers including the
last Number tracked.
}
method "get neighbors"
begin
put 0 on record "a" data //set it to 0 because we don't want to skip gaps
put 4 on record "b" data
put 1 on record "working sector" layout index
copy record "track 3 numbers" layout to record "working sector" layout

loop until record "a" data > record "b" data
begin
add 1 to record "working sector" layout index //next item in list

Locate Number Right record "a" data //# of sectors to the Right
from record "track 3 numbers" layout //Number pointed by layout index
to Record "working sector" layout //a list of numbers to right

add 1 to record "working sector" layout index //next item in list

Locate Number Left record "a" data //# of sectors to the Left
from record "track 3 numbers" layout //Number pointed by layout index
to Record "working sector" layout //a list of numbers to right

add 1 to record "a" data //counter up to 5
end

call "count hits from sectors"
end

{This method will performs two LOOPS. The Outer LOOP loops through the working
sector numbers (all 11 of them). The Inner LOOP loops through the record wheel
until a match is found. Then gets the number of hits and stores into the
record working sector's data section.
}
method "count hits from sectors"
begin
put 1 on record "working sector" layout index
put 0 on record "working sector" data

loop until record "working sector" Layout index > record "working sector" Layout count
begin
set flag "found" to false
put 1 on record "wheel" data index
put 1 on record "wheel" layout index

loop until record "wheel" layout index > record "wheel" layout count
or flag "found" is true
begin
if record "working sector" layout = record "wheel" layout
begin
add 100% of record "wheel" data to record "working sector" data
set flag "found" to true
end

add 1 to record "wheel" data index
add 1 to record "wheel" layout index
end

add 1 to record "working sector" Layout index
end
end

{This method takes the last number that came up and adds to the record wheel
which is a collections of numbers from the wheel. Supports both single and
double zero wheels.
}
method "update hits"
begin
put 1 on record "wheel" data index
put 1 on record "wheel" layout index

loop until record "wheel" layout index > record "wheel" layout count
begin
if record "last number" layout = record "wheel" layout
begin
add 1 to record "wheel" data
return
end

add 1 to record "wheel" data index
add 1 to record "wheel" layout index
end
end


method "input"
begin
group
begin
input data "Enter Win Stop" to record "win stop" data
input dropdown "Enter Roulette Layout:

1:=Single Wheel
2:=Double Wheel" to record "layout type" data

input dropdown "Enter Progression Type:

1:=Flat Bet
2:=Ivory Style
3:=Even Profit" to record "progression type" data

input dropdown "Enter Waiting Period:

1:=Choose Lastest Lowest
2:=Only When Lowest is Found" to record "wait to bet" data
end

add 100% of bankroll to record "win stop" data
if record "layout type" data = 1
begin
load single wheel
end
else
begin
load double wheel
end

if record "progression type" data = 1
begin
duplicate record "flat bet" to record "progression"
end

if record "progression type" data = 2
begin
duplicate record "ivor style" to record "progression"
end

if record "progression type" data = 3
begin
duplicate record "even profit" to record "progression"
end
end

method "reset"
begin
clear record "wheel" data
put 0 on record "spin count" data
clear record "sector 1" layout
clear record "sector 2" layout
clear record "sector 3" layout
end

method "init"
begin
put 200 on record "win stop" data
put 100% of bankroll on record "bankroll" data
clear record "last number" data
clear record "progression" data
set list [1,1,1,1,1,1,1] to record "flat bet" data
set list [4,5,6,8,11,15,21] to record "ivor style" data
set list [1,2,3,4,6,9,13] to record "even profit" data

clear record "track 3 numbers" layout
copy list [number 1, number 2, number 3, number 4, number 5, number 6,
number 7,
number 8, number 9, number 10,number 11,number 12,number 13,
number 14,number 15,number 16,number 17,number 18,number 19,
number 20,number 21,number 22,number 23,number 24,number 25,
number 26,number 27,number 28,number 29,number 30,number 31,
number 32,number 33,number 34,number 35,number 36,number 0,
number 00] to record "wheel" layout

clear record "working sector" layout
end