The Duke Of York System

Contenuto del file

system "The Duke Of York System"
{
*************************************
*        System by Paul             *
*       on the VIP Lounge           *
*************************************
        Rx-ed by St0rm0r

Split wheel up into 4 sections
Group()
(1) 28,9,26,30,11,7,20,32,17
(2) 5,22,34,15,3,24,36,13,1
(3) 27,10,25,29,12,8,19,31,18
(4) 6,21,33,16,4,23,35,14,2

Each time one of the above numbers hits mark down which
group the number belongs to. Say 28 hits this is group 1.

Then record 38 Spins

Example of how your results may look :
1. 7 times
2. 9
3. 14
4. 8

Then record another 38 spins :
1. 12 times
2. 8
3. 10
4. 9

Then combine the two totals (deduct one from the other).
1. 12-7= + 5
2. 8-9= -1
3. 10-14= -4
4. 9-8= 1

You play the group with the biggest -.
So for the next 38 spins we play group 3. (start play at this point).

progression add one unit on a loss reset on a win.
}
method "main"
begin
// section 1: do this once
while starting new session
    begin
    call "init"
    exit
    end

// section 2: do the tracking
track last number for 1 time record"last#"layout
if record"last#"layout = number 0 and flag "qualified" false
    begin
    exit
    end
track last number for 76 spins record"last 76"layout
if record"last 76"layout count < 76
    begin
    exit
    end
// section 3: act on a loss
if net < 0
    begin
    add 1 record"unit"data
    end

// section 4:act on a win
if net > 0
    begin
    put 1 record"unit"data
    end
// section 5: what to do when not qualified
if flag "qualified" false
    begin
    put 1 record"last 76"layout index
    loop until record"last 76"layout index = 39
        begin
        put 0 record"1st run"data index
        if record"last 76"layout is found in record"group 1"layout
            begin put 1 record"1st run"data index end
        if record"last 76"layout is found in record"group 2"layout
            begin put 2 record"1st run"data index end
        if record"last 76"layout is found in record"group 3"layout
            begin put 3 record"1st run"data index end
        if record"last 76"layout is found in record"group 4"layout
            begin put 4 record"1st run"data index end
        add 1 record"1st run"data
        add 1 record"last 76"layout index
        end
    put 39 record"last 76"layout index
    loop until record"last 76"layout index > record"last 76"layout count
        begin
        put 0 record"2nd run"data index
        if record"last 76"layout is found in record"group 1"layout
            begin put 1 record"2nd run"data index end
        if record"last 76"layout is found in record"group 2"layout
            begin put 2 record"2nd run"data index end
        if record"last 76"layout is found in record"group 3"layout
            begin put 3 record"2nd run"data index end
        if record"last 76"layout is found in record"group 4"layout
            begin put 4 record"2nd run"data index end
        add 1 record"2nd run"data
        add 1 record"last 76"layout index
        end
    put 1 record"1st run"data index
    loop until record"1st run"data index > record"1st run"data count
        begin
        put 100% record"1st run"data index in record"2nd run"data index
        put 100% record"1st run"data index in record"difference"data index
        put 100% record"2nd run"data in record"difference"data
        subtract 100% record"1st run"data from record"difference"data
        add 1 record"1st run"data index
        end
    put 0 record"play"data
    put 9999 in record"lowest"data
    put 1 record"difference"data index
    loop until record"difference"data index > record"difference"data count
        begin
        if record"difference"data < record"lowest"data
            begin
            put 100% record"difference"data in record"lowest"data
            put 100% record"difference"data index in record"play"data
            end
        add 1 record"difference"data index
        end
    set flag "qualified" true
    end

// section 6: what to do when qualified
if flag "qualified" true
    begin
    // bet
    if record"play"data = 1
        begin put 100% record"unit"data record"group 1"layout list end
    if record"play"data = 2
        begin put 100% record"unit"data record"group 2"layout list end
    if record"play"data = 3
        begin put 100% record"unit"data record"group 3"layout list end
    if record"play"data = 4
        begin put 100% record"unit"data record"group 4"layout list end
    add 1 record"#bets"data
    if record"#bets"data = 38
        begin
        call"reset"
        end
    end

end

// subroutines
method "init"
begin
copy list [number 28,number 9,number 26,number 30,number 11,number 7,number 20,
number 32,number 17] record"group 1"layout
copy list [number 5,number 22,number 34,number 15,number 3,number 24,number 36,
number 13,number 1] record"group 2"layout
copy list [number 27,number 10,number 25,number 29,number 12,number 8,number 19,
number 31,number 18] record"group 3"layout
copy list [number 6,number 21,number 33,number 16,number 4,number 23,number 35,
number 14,number 2] record"group 4"layout
call "reset"
end

method "reset"
begin
clear record"last 76"layout
set flag "qualified" false
set list [0,0,0,0] record"1st run"data
set list [0,0,0,0] record"2nd run"data
set list [0,0,0,0] record"difference"data
put 1 record"unit"data
put 0 record"#bets"data
end