Slam Dunk System

Contenuto del file

system "Slam_Dunk_System"

{
For instructions, visit: http://gambling.projectsydney.com/viewtopic.php?t=1462

Designed by Handle
Coded by UX Software
}
method "main"
begin
    while Starting a new Session
    begin
        call "init"
    end

    if record "Split 0/2/3" Layout list has lost each time
    and record "Corners 4/5/7/8, 25/26/28/29" Layout list has lost each time
    and record "Splits 12-15,18-21,19-22,32-35" Layout list has lost each time
    begin
        if flag "High Bet" is true
        begin
            set max to record "HIGH" data index
            add 1 to record "HIGH" data index
            put 100% of record "bet" data to record "HIGH" data
        end
        else
        begin
            call "Add lost bet to beginning"
        end

        set flag "High Bet" to false
    end

    if any inside bet has won each time
    begin
        if flag "High Bet" is true
        begin
            call "Remove from items from list"
        end

        set flag "High Bet" to true
    end

    if flag "High Bet" is true
    begin
        call "Do HIGH bet"
    end
    else
    begin
        put 1 unit to record "bet" data
        put 300% of record "bet" data to record "Split 0/2/3" layout list
        put 200% of record "bet" data to record "Splits 12-15,18-21,19-22,32-35" layout list
        put 400% of record "bet" data to record "Corners 4/5/7/8, 25/26/28/29" layout list
    end
end

//"HIGH" means a high bet which is the sum of the first and last numbers
//in the progression
method "Do HIGH bet"
begin
    put 0 on record "bet" data
    put 1 on record "LOW" data index

    loop until record "LOW" data index > record "LOW" data count
    begin
        add 100% of record "LOW" data to record "bet" data
        add 1 to record "LOW" data index
    end

    if record "bet" data = 0
    begin
        if record "HIGH" data count > 1
        begin
            put 1 on record "HIGH" data index
            put 100% of record "HIGH" data to record "bet" data
        end
    end

    set max to record "HIGH" data index
    add 100% of record "HIGH" data to record "bet" data

    if record "bet" data = 0
    begin
        put 1 on record "bet" data
    end

    put 300% of record "bet" data to record "Split 0/2/3" layout list
    put 200% of record "bet" data to record "Splits 12-15,18-21,19-22,32-35" layout list
    put 400% of record "bet" data to record "Corners 4/5/7/8, 25/26/28/29" layout list
end

//Any "LOW" bet lost is added to the beginning of the progression
method "Add lost bet to beginning"
begin
    duplicate record "LOW" to record "temp"
    clear record "LOW" data
    put 1 on record "temp" data index
    put 2 on record "LOW" data index

    loop until record "temp" data index > record "temp" data count
    begin
        put 100% of record "temp" data to record "LOW" data
        add 1 to record "temp" data index
        add 1 to record "LOW" data index
    end

    put 1 to record "LOW" data index
    put 100% of record "bet" data to record "LOW" data
end

//Won with HIGH bet placed. Remove HIGH and LOW from list
method "Remove from items from list"
begin
    //remove last item in HIGH list
    duplicate record "HIGH" to record "temp"
    clear record "HIGH" data
    set max to record "temp" data index
    put 100% of record "temp" data index to record "max HIGH" data
    subtract 1 from record "max HIGH" data

    put 1 on record "temp" data index
    put 1 on record "HIGH" data index

    if record "LOW" data count = 0
    begin
        add 1 to record "temp" data index
    end

    loop until record "temp" data index > record "max HIGH" data
    begin
        put 100% of record "temp" data to record "HIGH" data
        add 1 to record "temp" data index
        add 1 to record "HIGH" data index
    end

    //remove all items in LOW list
    clear record "LOW" data

    if record "HIGH" data count = 0
    begin
        add 1 to record "session count" data
        put 1 on record "LOW" data
        clear record "HIGH" data
    end
end

method "init"
begin
    Load Single Wheel
    set flag "High Bet" to true
    put 0 to record "session count" data
    put 0 on record "bet" data
    put 1 on record "LOW" data
    clear record "HIGH" data
    copy list [Street(0-3)] to record "Split 0/2/3" layout
    copy list [Split(12-15),Split(18-21),Split(19-22),Split(32-35)] to record "Splits 12-15,18-21,19-22,32-35" layout
    copy list [Corner(4:8),Corner(25:29)] to record "Corners 4/5/7/8, 25/26/28/29" layout
end