Original 50max system

Contenuto del file

system "Original 50max system"
{
  See 50max on Vip lounge.

  http://gambling.projectsydney.com/viewtopic.php?t=202&highlight=50max

  starting minimum bet is 5 units on even/odd.
}
method "main"
begin
    while starting a new session
    begin
        call "init"
        call "input"
        exit
    end

    if flag "Stop Session" is true
    begin
        Exit
    end

    if Any Inside Bet has won each time
    or Any Outside Bet has won each time
    begin
        multiply 100% of record "inc" data to record "bet" data
        add 100% of record "bet" data to record "balance" data

        if  record "Win Goal" data is not = 0
        and record "balance" data >= record "Win Goal" data
        begin
            Display "You have reached your Win goal.  Session is stop."
            set flag "Stop Session" to true
            Stop Session
            exit
        end
    end

    if Any Inside Bet has lost each time
    or Any Outside Bet has lost each time
    begin
        if Number 0 has hit each time
        or Number 00 has hit each time
        begin
            divide 2 to record "bet" data

            //next steps Truncates any fractions to the lowest number
            add 100% of record "truncate" data to record "bet" data
            put 100% of record "bet" data to record "bet" data index
            //End of truncate function.
            subtract 100% of record "bet" data index to record "balance" data
            put 1 on record "bet" data index
        end
        else
        begin
            subtract 100% of record "bet" data to record "balance" data
        end
    end

    if Number 0 has hit each time
    or Number 00 has hit each time
    begin
        exit
    end

    if flag "first bet" is true
    begin
        call "determine layout"
        put 100% of record "bet" data to record "layout" layout
        set flag "first bet" to false
        exit
    end

    add 2 to record "goal" data
    call "determine balance"
    call "determine bet"
    call "determine layout"

    put 100% of record "bet" data to record "layout" layout
end

method "determine layout"
begin
    if record "pointer" data = 1
    begin
        copy last Odd-Even to record "layout" layout
        put 1 on record "inc" data
    end

    if record "pointer" data = 2
    begin
        copy last Dozen to record "layout" layout
        put 2 on record "inc" data
    end

    if record "pointer" data = 3
    begin
        copy last Line to record "layout" layout
        put 5 on record "inc" data
    end

    if record "pointer" data = 4
    begin
        copy last corner to record "layout" layout
        put 8 on record "inc" data
    end

    if record "pointer" data = 5
    begin
        copy last street to record "layout" layout
        put 11 on record "inc" data
    end

    if record "pointer" data = 6
    begin
        copy last split to record "layout" layout
        put 17 on record "inc" data
    end

    if record "pointer" data = 7
    begin
        copy last number to record "layout" layout
        put 35 on record "inc" data
    end
end

method "determine bet"
begin
    set flag "found" to false

    if record "pointer" data = 1
    begin
        duplicate record "even" to record "temp"
        call "calc bet"

        if flag "found" is true
        begin
            return
        end

        add 1 to record "pointer" data
    end

    if record "pointer" data = 2
    begin
        duplicate record "dozen" to record "temp"
        call "calc bet"

        if flag "found" is true
        begin
            return
        end

        add 1 to record "pointer" data
    end

    if record "pointer" data = 3
    begin
        duplicate record "lane" to record "temp"
        call "calc bet"

        if flag "found" is true
        begin
            return
        end

        add 1 to record "pointer" data
    end

    if record "pointer" data = 4
    begin
        duplicate record "square" to record "temp"
        call "calc bet"

        if flag "found" is true
        begin
            return
        end

        add 1 to record "pointer" data
    end

    if record "pointer" data = 5
    begin
        duplicate record "street" to record "temp"
        call "calc bet"

        if flag "found" is true
        begin
            return
        end

        add 1 to record "pointer" data
    end

    if record "pointer" data = 6
    begin
        duplicate record "split" to record "temp"
        call "calc bet"

        if flag "found" is true
        begin
            return
        end

        add 1 to record "pointer" data
    end

    if record "pointer" data = 7
    begin
        duplicate record "straight" to record "temp"
        call "calc bet"

        if flag "found" is true
        begin
            return
        end
    end

    call "reset"
end

method "calc bet"
begin
    put 1 on record "temp" data index
    loop until record "temp" data index > record "temp" data count
    or   record "temp" data >= record "bet" data
    begin
        put 100% of record "temp" data index to record "unit" data index
        add 1 to record "temp" data index
    end

    if record "temp" data index <= record "temp" data count
    begin
        put 100% of record "temp" data index to record "unit" data index
        put 100% of record "unit" data on record "bet" data
        set flag "found" to true
    end
end

method "determine balance"
begin
    put 0 on record "bet" data

    if record "balance" data < record "goal" data
    begin
        if record "balance" data < 0
        begin
            put 100% record "balance" data to record "bet" data
            multiply -1 on record "bet" data
            add 100% of record "goal" data to record "bet" data
        end
        else
        begin
            put 100% of record "goal" data to record "bet" data
            subtract 100% record "balance" data to record "bet" data
        end

        if record "bet" data < 5 then
        begin
            call "reset"
        end
    end
    else
    begin
        call "reset"
    end
end

method "reset"
begin
    put 5 on record "bet" data
    put 1 on record "pointer" data
    put 1 on record "unit" data index
    put 1 on record "even" data index
    put 1 on record "dozen" data index
    put 1 on record "lane" data index
    put 1 on record "street" data index
    put 1 on record "split" data index
    put 1 on record "square" data index
    put 1 on record "straight" data index
    put 1 on record "inc" data
    put 0 on record "balance" data
    put 2 on record "goal" data
end

method "init"
begin
    set flag "Stop Session" to false
    set flag "first bet" to true
    put 0 on record "bet" data
    put 0 on record "spin" data
    put 2 on record "goal" data
    put 100% of bankroll on record "initial bankroll" data
    put 0 on record "balance" data
    put 1 on record "pointer" data
    put 1 on record "truncate" data
    subtract 50% of record "truncate" data to record "truncate" data
    put 100 on record "Win Goal" data

    set list [5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,
              31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,50] to
              record "unit" data

    set list [5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,
              31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51] to
              record "even" data

    set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,52,54,56,
              58,60,62,64,66,68,70,72,74,76,78,80,82,84,86,88,90,92,94,96,98,100,104] to
              record "dozen" data

    set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,105,110,115,120,125,
              130,135,140,145,150,155,160,165,170,175,180,185,190,195,200,205,210,
              215,220,225,230,235,240,245,250,255] to record "lane" data

    set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
              0,0,0,0,0,0,0,0,256,264,272,280,288,296,304,312,320,
              328,336,344,352,360,368,376,384,392,400,406] to record "square" data

    set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
              0,0,0,0,0,0,0,0,0,0,0,0,0,407,418,429,440,451,
              462,473,484,495,506,517,528,539,550,560] to record "street" data

    set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
              0,0,0,0,0,0,0,0,0,0,561,578,595,612,629,646,663,680,
              697,714,731,748,765,782,799,816,833,850,876] to record "split" data

    set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
              0,0,875,910,945,980,1015,1050,1085,1120,1155,1190,1225,1260,1295,1330,
              1365,1400,1435,1470,1505,1540,1575,1610,1645,1680,1715,1750,1750] to
              record "straight" data

    call "reset"
end

method "input"
begin
    Group
    begin
        Input Dropdown "What Table Layout do you want to use?

                  1:=European Layout
                  2:=American Layout" to Record "Table Layout" data;

        Input Data "Enter your starting Bankroll." to Record "Starting Bankroll" data;
        Input Data "What is your Maximum Win Goal." to Record "Win Goal" data;
    end

    Put 100 % of Record "Starting Bankroll" data on Bankroll;

    While Record "Table Layout" data = 1
    begin
        Load Single Wheel;
    end
    Else
    begin
        Load Double Wheel;
    end
end