No More Sleepers System I v2

Contenuto del file

system "No More Sleepers System I v2"
{
*************************************
*         System by Apache          *
*         on the VIP Lounge         *
*************************************
          Rx-ed by St0rm0r

If in the last 12 spins we don't have a repetition
we bet on this 12 numbers with a progression.
After hit, we reset the progression and we look for next opportunity to bet.
If we get a repetition while betting, we stop our bet.
}
method "main"
begin
// section 1: do this once
while starting new session
    begin
    call "init"
    exit
    end

// section 2: do the tracking
track last number for record"how many"data record"last N"layout
if record"last N"layout count < record"how many"data
    begin
    exit
    end

subtract 100% net record"loss"data
if bankroll > record"new high"data
    begin
    put 100% bankroll in record"new high"data
    put 0 record"loss"data
    put 1 record"pro"data
    end

// section 3: act on a loss
if net < 0
    begin
    if record"type"data = 2 or record"type"data = 4
        begin
        add 1 record"pro"data
        end
    end

if record"type"data = 3
    begin
    if record"loss"data > 0
        begin
        call "calculate progression1"
        end
        else
        begin
        put 1 record"pro"data
        end
    end

// section 4:act on a win
if net > 0
    begin
    set flag "qualified" false
    if record"type"data = 2
        begin
        put 1 record"pro"data
        end
    if record"type"data = 4
        begin
        subtract 1 record"pro"data
        if record"pro"data < 1
            begin
            put 1 record"pro"data
            end
        end
    if record"type"data = 5
        begin
        if bankroll < record"new high"data
            begin
            add 1 record"pro"data
            end
        end
    end

// section 5:act when not qualified
if flag "qualified" false
    begin
    duplicate record"last N" record"play"
    call "update frequencies"
    if flag "no repeater" true
        begin
        set flag "qualified" true
        end
    end

// section 6:act when  qualified
if flag "qualified" true
    begin
    call "update frequencies"
    if flag "no repeater" true
        begin
        put 100% record"pro"data on record"play"layout list
        end
        else
        begin
        set flag "qualified" false
        end
    end

end

// subroutines
method "init"
begin
group
    begin
    display "No More Sleepers System I v1"
    display "by Apache"
    input data "Start playing when x spins without repeaters: (e.g. 12)" record"how many"data
    input dropdown "Progression:
    1:= Flat bet
    2:= 1,2,3,4,5,....
    3:= Enough to get positive in 1 win
    4:= +1 on a loss, -1 on a win
    5:= Turbo's gift" record"type"data
    end
copy list [number 0, number 1, number 2, number 3,number 4,number 5,number 6,
number 7,number 8,number 9,number 10,number 11,number 12,number 13,number 14,
number 15,number 16,number 17,number 18,number 19,number 20,number 21,number 22,
number 23,number 24,number 25,number 26,number 27,number 28,number 29,number 30,
number 31,number 32,number 33,number 34,number 35,number 36] to record"numbers"layout
set flag "qualified" false
put 0 record"loss"data
put 100% bankroll in record"new high"data
put 1 record"pro"data
end

method "update frequencies"
begin
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
0,0,0] record"hit frequencies"data
set flag "no repeater" true
put 1 record"last N"layout index
loop until record"last N"layout index > record"last N"layout count
    begin
    put 1 record"numbers"layout index
    loop until record"numbers"layout = record"last N"layout
        begin
        add 1 record"numbers"layout index
        end
    put 100% record"numbers"layout index record"hit frequencies"data index
    add 1 record"hit frequencies"data
    if record"hit frequencies"data > 1
        begin
        set flag "no repeater" false
        end
    add 1 record"last N"layout index
    end
end

method "calculate progression1"
begin
put 0 record "pro"data
put 100% record"loss"data in record"ref"data
loop until record"ref"data < 0
    begin
    add 100% record"how many"data to record"ref"data
    subtract 36 record"ref"data
    add 1 record "pro"data
    end
end