Sleeper Test III

Contenuto del file

system "Krev Sleeper Test III"
{
*************************************
*       Test System to Krev         *
*       on the VIP Lounge           *
*************************************
        Rx-ed by St0rm0r

Track until 12 sleepers left.
Then start betting the 25 non sleepers.
+1 on a loss
-1 on a win
restart tracking on a new high
}
method "main"
begin
// section 1: do this once
while starting new session
    begin
    call "init"
    exit
    end

// section 2: do the tracking
track last number for 1 time in record"last#"layout
call "update frequency"

// section 3: act on a loss
if net < 0
    begin
    add 1 record"bet unit"data

    end
// section 4:act on a win
if net > 0
    begin
    subtract 1 record"bet unit"data
    if record"bet unit"data < 1
        begin
        put 1 record"bet unit"data
        end
    if bankroll > record"new high"data
        begin
        call"reset"
        end
    end


// section 5: what to do when not qualified
if flag "qualified" false
    begin
    call "determine number sleepers"
    if record"# sleepers"data = 12
        begin
        duplicate record"history" record"bet on"
        set flag "qualified" true
        end
    end

// section 6: what to do when qualified
if flag "qualified" true
    begin
    // bet
    put 1 record"bet on"data index
    loop until record"bet on"data index > record"bet on"data count
        begin
        if record"bet on"data > 0
            begin
            put 100% record"bet on"data index record"numbers"layout index
            put 100% record"bet unit"data on record"numbers"layout
            end
        add 1 record"bet on"data index
        end
    end

end

// subroutines
method "init"
begin
copy list [number 0, number 1, number 2, number 3,number 4,number 5,number 6,
number 7,number 8,number 9,number 10,number 11,number 12,number 13,number 14,
number 15,number 16,number 17,number 18,number 19,number 20,number 21,number 22,
number 23,number 24,number 25,number 26,number 27,number 28,number 29,number 30,
number 31,number 32,number 33,number 34,number 35,number 36] to record"numbers"layout
put 1 record"bet unit"data
call "reset"
end

method "reset"
begin
put 100% bankroll record"new high"data
set flag "qualified" false
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
0,0] record"history"data
end

method "update frequency"
begin
put 1 record"numbers"layout index
loop until record"numbers"layout = record"last#"layout
    begin
    add 1 record"numbers"layout index
    end
put 100% record"numbers"layout index record"history"data index
add 1 record"history"data
end

method "determine number sleepers"
begin
put 0 record"# sleepers"data
put 1 record"history"data index
loop until record"history"data index > record"history"data count
    begin
    if record"history"data = 0
        begin
        add 1 record"# sleepers"data
        end
    add 1 record"history"data index
    end
end