Mythtical system

Contenuto del file

system "Mythtical System "
{
NOTE: ** For Version 2.0.13 or better **

See documentation for instructions.

Basic input instructions
1. Enter your initial starting bankroll
2. Select what wheel type to use. American or European
3. How many spins to track.  The book says use 37 so that is the default.
4. Enter a Stop WIN amount.
5. Enter a Stop LOSS amount.
6. Enter number of sequences.  A sequence here according to the book is a session
   that is played.  A session ends when one of the following occurs:
        A: You have played out all of the tracked spins (i.e. 37)
        B: You have reached your Stop WIN amount
        C: You have reached your Stop LOSS amount
}
method "main"
begin
    while starting a new session
    begin
      call "initialize"
      call "input"
      exit
    end
    
    if  any inside bet has won each time
    begin
        if  record "stop win bankroll" data not = record "bankroll" data
        and bankroll >= record "stop win bankroll" data
        begin
            set flag "finish sequence" to true
            add 1 to record "sequence count" data
            put 100% of bankroll to record "bankroll" data
            call "Setup Stop Win/Loss"
        end
    end

    if  record "stop loss bankroll" data not = record "bankroll" data
    and bankroll < record "stop loss bankroll" data
    begin
        set flag "finish sequence" to true
        add 1 to record "sequence count" data
        put 100% of bankroll to record "bankroll" data
        call "Setup Stop Win/Loss"
    end

    if record "sequences" data > 0
    begin
        if record "sequence count" data >= record "sequences" data
        begin
            display "All sequences have completed. Session will End."
            stop Session
        end
    end
    
    add 1 to record "spin count" data
    track last number of record "track count" data to record "track spins" layout

    if  flag "initial track complete" is true
    and record "spin count" data >= record "track count" data
    begin
        put 0 on record "spin count" data
        set flag "initial track complete" to false
        set flag "finish sequence" to false
        clear record "track spins" layout
        clear record "numbers that come up" layout
        clear record "numbers to bet" layout
        put 100% of bankroll to record "bankroll" data
        call "Setup Stop Win/Loss"
        exit
    end
    
    if  record "track count" data = record "spin count" data
    and flag "initial track complete" is false
    begin
        set flag "initial track complete" to true
        put 0 on record "spin count" data
        duplicate record "track spins" to record "numbers that come up"
        exit
    end
    
    if  flag "initial track complete" is true
    and record "track spins" layout is not found in record "numbers that come up" layout
    and record "track spins" layout is not found in record "numbers to bet" layout
    and flag "finish sequence" is false
    begin
        add 1 to record "numbers to bet" layout index
        copy record "track spins" layout to record "numbers to bet" layout
    end
    
    if  record "numbers to bet" layout index > 0 then
    and flag "finish sequence" to false
    begin
        put 1 unit on record "numbers to bet" layout list
    end
end

method "input"
begin
    group
    begin
        display "Mythtical's System"
        input data "Enter starting bankroll" to record "bankroll" data
        input dropdown "Wheel type
        
                        1:=Single Zero
                        2:=Double Zero" to record "wheel type" data
        input data "How many spins to track?" to record "track count" data
        input data "Enter Stop WIN in units" to record "stop win" data
        input data "Enter Stop LOSS in units" to record "stop loss" data
        input data "Enter number of sequences
        
                    Sequences are individual sessions played
                    determined by Stop Win, Stop Loss or Spins Track."
                                                            to record "sequences" data
    end
    
    if record "wheel type" data = 1
    begin
        load single wheel
    end
    else
    begin
        load double wheel
    end
    
    call "Setup Stop Win/Loss"
end

method "Setup Stop Win/Loss"
begin
    //set Bankroll
    put 100% of record "bankroll" data to bankroll

    //calculate stop Win bankroll
    put 100% of record "bankroll" data to record "stop win bankroll" data
    add 100% of record "stop win" data to record "stop win bankroll" data
    
    //calculate stop Loss bankroll
    put 100% of record "bankroll" data to record "stop loss bankroll" data
    subtract 100% of record "stop loss" data to record "stop loss bankroll" data
end

method "initialize"
begin
    put 0 on record "spin count" data
    set flag "initial track complete" to false
    put 0 on record "sequence count" data
    put 100% of bankroll to record "bankroll" data
    clear record "track spins" layout
    clear record "numbers that come up" layout
    clear record "numbers to bet" layout
    put 0 on record "numbers to bet" layout index
    
    put 37 on record "track count" data
end