Line System Units

Contenuto del file

system "Line System Units = Spins"
{
 *************************
 * System by TurboGenius *
 *   on the VIP Lounge   *
 *************************
 Sun Apr 17, 2005 2:06 am
    Rx-ed by St0rm0r

Method :
" We record until we have only one lane (line/double street) left to show.
We keep going until it finally does show.
We bet in units on it now the same amount as the number of spins that it took to show.
On a win, if we are ahead we start over.
On a win, if we are still behind, we add the number of spins that it took to get this win to our units and continue.
-
Actually - it might make the most sense to play for 6 spins max,
if no win by then we stop betting but still count the spins until the next
show (add this to our previous bet amount) and then begin playing again.
Once you're past the 6th spin you can't make a profit anyway. "
}

method "main"
begin
while starting new session
    begin
    call "reset"
    exit
    end

if flag "qualify" is true
// if we made a bet...
begin
if record"sleeper line"layout not hit each time
    //...and lost it
    begin
    add 1 to record"miss tracker"data
    end

if record"sleeper line"layout hit each time
    //...and won it
    begin
        if bankroll > record"ref bank"data
        //...and we are ahead
        begin
        call "reset"
        end
        else
        //...and we are behind
        begin
        add 100% of record"miss tracker"data to record"bet size"data
        put 0 to record"miss tracker"data
        end
    end
end

track last Street for 1 time in record"street history"layout
call "update line history table"
call "check if last line just has come up"

if flag "qualify" true
begin
//place a bet
    if record"bet size"data > 99
        begin
        // if bet size > 99 then reset (assumed table limit of 100)
        call "reset"
        end
    // play for 6 spins max
    if record"miss tracker"data < 7
        begin
        put 100% of record"bet size"data on record"sleeper line"layout
        end
end

end

method "reset"
begin
set flag "qualify" false
set list [0,0,0,0,0,0] to record"previous line history"data
set list [0,0,0,0,0,0] to record"line history"data
put 100% of bankroll to record"ref bank"data
put 0 in record"bet size"data
put 0 to record"miss tracker"data
end

method "update line history table"
begin
//copy line history list to previous line history list
put 1 in record"line history"data index
loop until record"line history"data index > record"line history"data count
    begin
    put 100% of record"line history"data index in record"previous line history"data index
    put 100% of record"line history"data in record"previous line history"data
    add 1 to record"line history"data index
    end

//update line history list
if record"street history"layout = Street(1-3) or record"street history"layout = Street(4-6)
    begin
    put 1 in record"line history"data index
    end
if record"street history"layout = Street(7-9) or record"street history"layout = Street(10-12)
    begin
    put 2 in record"line history"data index
    end
if record"street history"layout = Street(13-15) or record"street history"layout = Street(16-18)
    begin
    put 3 in record"line history"data index
    end
if record"street history"layout = Street(19-21) or record"street history"layout = Street(22-24)
    begin
    put 4 in record"line history"data index
    end
if record"street history"layout = Street(25-27) or record"street history"layout = Street(28-30)
    begin
    put 5 in record"line history"data index
    end
if record"street history"layout = Street(31-33) or record"street history"layout = Street(34-36)
    begin
    put 6 in record"line history"data index
    end
add 1 to record"line history"data
end

method "check if last line just has come up"
begin
// check that only 1 line has history = 0
put 0 in record"0 counter"data
put 1 in record"previous line history"data index
loop until record"previous line history"data index > record"previous line history"data count
    begin
    if record"previous line history"data = 0
        begin
        add 1 to record"0 counter"data
        end
    add 1 to record"previous line history"data index
    end
if record"0 counter"data = 1
    begin
    // identify sleeper line
    put 1 in record"line history"data index
    loop until record"line history"data index > record"line history"data count
        begin
        put 100% of record"line history"data index in record"previous line history"data index
        if record"line history"data = 1 and record"previous line history"data = 0
            begin
            // now we're qualified to bet
            set flag "qualify" true
            if record"line history"data index = 1
                begin
                copy Line(1-6) to record"sleeper line"layout
                end
            if record"line history"data index = 2
                begin
                copy Line(7-12) to record"sleeper line"layout
                end
            if record"line history"data index = 3
                begin
                copy Line(13-18) to record"sleeper line"layout
                end
            if record"line history"data index = 4
                begin
                copy Line(19-24) to record"sleeper line"layout
                end
            if record"line history"data index = 5
                begin
                copy Line(25-30) to record"sleeper line"layout
                end
            if record"line history"data index = 6
                begin
                copy Line(31-36) to record"sleeper line"layout
                end
            end
        add 1 to record"line history"data index
        end
    call "calculate bet size"
    put 0 in record"miss tracker"data
    end
end

method "calculate bet size"
begin
put 0 in record"bet size"data
put 1 in record"line history"data index
loop until record"line history"data index > record"line history"data count
    begin
    add 100% of record"line history"data to record"bet size"data
    add 1 to record"line history"data index
    end
end