Leader Variation v2

Contenuto del file

system "Leader Variation v2"
{
*************************************
*      System by slamdunkfunkk      *
*         on the VIP Lounge         *
*************************************
          Rx-ed by St0rm0r
-------------------------------------
           00-c0mpatible
-------------------------------------
1. Track 12 spins
2. Pick the number(s) that have hit the most.
If all numbers have hit 1 time, track another 12 spins
3. Play 1 unit per number
4. Play for 12 spins, come what may, then pick new leader(s)
out of all historical spins. When a leader has been hit 8 times, reset history.
5. If in profit after 12 spins, reset to 1 unit per number
6. If behind, add 1 unit to the betting amount per number
7. Reset to 1 unit per number on a new profit high after 12 spins
-------------------------------------
}
method "main"
begin
//  do this once
while starting new session
    begin
    call "init"
    exit
    end

// do the tracking
track last number for 12 times record"last 12"layout
//update frequency list
put 1 record"numbers"layout index
loop until record"numbers"layout = record"last 12"layout
    begin
    add 1 record"numbers"layout index
    end
put 100% record"numbers"layout index record"frequency"data index
add 1 record"frequency"data

if record"last 12"layout count < 12
    begin
    exit
    end

if record"#bets"data = 12
    begin
    if bankroll > record"high"data
        begin
        put 100% bankroll record"high"data
        put 1 record"pro"data
        end
        else
        begin
        add 1 record"pro"data
        end
    call "reset"
    end

// act on a win
if net > 0
    begin
    if record"H"data = 2
        begin
        set flag "don't bet" true
        end
    end

// act when not qualified
if flag "qualified" false
    begin
    //determine maximum hit
    put 0 record"max"data
    put 1 record"frequency"data index
    loop until record"frequency"data index > record"frequency"data count
        begin
        if record"frequency"data > record"max"data
            begin
            put 100% record"frequency"data record"max"data
            end
        add 1 record"frequency"data index
        end
    //if maximum is 8 then reset history and go for another 12 spins
    if record"max"data >= 8
        begin
        clear record"last 12"layout
        clear record"play"layout
        put 0 record"#bets"data
        clear record"frequency"data
        set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] record"frequency"data
        put 1 record"pro"data
        exit
        end
    //if maximum is 1 then go for another 12 spins
    if record"max"data = 1
        begin
        clear record"last 12"layout
        clear record"play"layout
        put 0 record"#bets"data
        end
        else //make play list of leaders
        begin
        clear record"play"layout
        put 1 record"frequency"data index
        loop until record"frequency"data index > record"frequency"data count
            begin
            if record"frequency"data = record"max"data
                begin
                put 100% record"frequency"data index record"numbers"layout index
                copy record"numbers"layout record"play"layout
                add 1 record"play"layout index
                end
            add 1 record"frequency"data index
            end
        set flag "qualified" true
        put 0 record"#bets"data
        end
    end

// act when qualified
if flag "qualified" true
    begin
    //bet
    if flag "don't bet" false
        begin
        put 100% record"pro"data record"play"layout list
        end
    add 1 record"#bets"data
    end
end

// subroutines
method "init"
begin
group
    begin
    display "Leader Variation"
    display "----------------------------"
    input dropdown "On a hit, play up to 12 spins
    1:= in REAL mode
    2:= in VIRTUAL mode" record"H"data

    end
copy list [number 00, number 0, number 1, number 2, number 3,number 4,number 5,number 6,
number 7,number 8,number 9,number 10,number 11,number 12,number 13,number 14,
number 15,number 16,number 17,number 18,number 19,number 20,number 21,number 22,
number 23,number 24,number 25,number 26,number 27,number 28,number 29,number 30,
number 31,number 32,number 33,number 34,number 35,number 36] to record"numbers"layout
clear record"frequency"data
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] record"frequency"data
put 1 record"pro"data
put 100% bankroll record"high"data
call "reset"
end

method "reset"
begin
set flag "qualified" false
set flag "don't bet" false
end