Gamblers Fallacy v2 mod

(Stark | Spin-dizzy) Giocare le che si scostano di più dall'equilibrio teorico.
Xtreme icon Variation on Turbo's Gamblers Fallacy Ver 2.dgt — Xtreme, 9 KB (10069 bytes)
Contenuto del file

system "Variation on Turbo's Gamblers Fallacy Ver 2"
{
*************************************
*          System by Stark          *
*         on the VIP Lounge         *
*************************************
         Rx-ed by Sp1N-D1zZy
-------------------------------------
Preparation.
Chart last 37 spins.

1.Play the even chance that has the worst negative deviation of the expected one.

2.Bet so many chips as the Difference between expected and actual outcome rounded down.

We flat-bet until we have a win or for max 37 spins.

3.If we have a win (in total), or if we reach 37 spins, we re-evaluate,
which even chance shows the most negative deviation at the moment,
by considering the last 37 spins until then.
And we start all over again from 1.
-------------------------------------
}
method "main"
begin
while starting a new session
    begin
    Call "Init"
    end
add 1 record"Spins"data
add 1 record"Sub Session Spins"data
if net > 0
    begin
    call "Reset"
    end
Call "Track"
if flag "Bet" true
    begin
    Call "Which"
    end
if flag "Put units" true
    begin
    Call "Put units"
    end
end

Method "Put units"
begin
if record"Bet this chance" layout = red or record"Bet this chance" layout = black
    begin
    put 100% record"Expected"data record"Unit Size"data
    subtract 100% record"Temp 1"data record"Unit Size"data
    end
if record"Bet this chance" layout = high or record"Bet this chance" layout = low
    begin
    put 100% record"Expected"data record"Unit Size"data
    subtract 100% record"Temp 2"data record"Unit Size"data
    end
if record"Bet this chance" layout = odd or record"Bet this chance" layout = even
    begin
    put 100% record"Expected"data record"Unit Size"data
    subtract 100% record"Temp 3"data record"Unit Size"data
    end
if record"Bet times"data < 38
    begin
    put 100% record"Unit Size"data record"Bet this chance"layout
    add 1 record"Bet times"data
    end
    else
    begin
    call "Reset"
    end
end

Method "Which"
begin
put 1 record"Deviation"data index
put 100% record"Deviation"data record"Temp 1"data
add 1 record"Deviation"data index
put 100% record"Deviation"data record"Temp 2"data
if record"Temp 1"data < record"Temp 2" data
    begin
    copy red record"Potential Chance"layout
    add 1 record"Potential Chance"layout index
    end
if record"Temp 1"data > record"Temp 2" data
    begin
    copy black record"Potential Chance"layout
    add 1 record"Potential Chance"layout index
    end
if record"Temp 1"data = record"Temp 2" data
    begin
    copy number 0 record"Potential Chance"layout
    add 1 record"Potential Chance"layout index
    end
add 1 record"Deviation"data index
put 100% record"Deviation"data record"Temp 1"data
add 1 record"Deviation"data index
put 100% record"Deviation"data record"Temp 2"data
if record"Temp 1"data < record"Temp 2" data
    begin
    copy high record"Potential Chance"layout
    add 1 record"Potential Chance"layout index
    end
if record"Temp 1"data > record"Temp 2" data
    begin
    copy low record"Potential Chance"layout
    add 1 record"Potential Chance"layout index
    end
if record"Temp 1"data = record"Temp 2" data
    begin
    copy number 0 record"Potential Chance"layout
    add 1 record"Potential Chance"layout index
    end
add 1 record"Deviation"data index
put 100% record"Deviation"data record"Temp 1"data
add 1 record"Deviation"data index
put 100% record"Deviation"data record"Temp 2"data
if record"Temp 1"data < record"Temp 2" data
    begin
    copy odd record"Potential Chance"layout
    add 1 record"Potential Chance"layout index
    end
if record"Temp 1"data > record"Temp 2" data
    begin
    copy even record"Potential Chance"layout
    add 1 record"Potential Chance"layout index
    end
if record"Temp 1"data = record"Temp 2" data
    begin
    copy number 0 record"Potential Chance"layout
    add 1 record"Potential Chance"layout index
    end
put 1 record"Potential Chance"layout index
if record"Potential Chance"layout = red
    begin
    put 1 record"Deviation"data index
    put 100% record"Deviation"data record"Check Lowest"data
    add 1 record"Check Lowest"data index
    end
if record"Potential Chance"layout = black
    begin
    put 2 record"Deviation"data index
    put 100% record"Deviation"data record"Check Lowest"data
    add 1 record"Check Lowest"data index
    end
if record"Potential Chance"layout = number 0
    begin
    put 9999999999 record"Check Lowest"data
    add 1 record"Check Lowest"data index
    end
put 2 record"Potential Chance"layout index
if record"Potential Chance"layout = high
    begin
    put 3 record"Deviation"data index
    put 100% record"Deviation"data record"Check Lowest"data
    add 1 record"Check Lowest"data index
    end
if record"Potential Chance"layout = low
    begin
    put 4 record"Deviation"data index
    put 100% record"Deviation"data record"Check Lowest"data
    add 1 record"Check Lowest"data index
    end
if record"Potential Chance"layout = number 0
    begin
    put 9999999999 record"Check Lowest"data
    add 1 record"Check Lowest"data index
    end
put 3 record"Potential Chance"layout index
if record"Potential Chance"layout = odd
    begin
    put 5 record"Deviation"data index
    put 100% record"Deviation"data record"Check Lowest"data
    add 1 record"Check Lowest"data index
    end
if record"Potential Chance"layout = even
    begin
    put 6 record"Deviation"data index
    put 100% record"Deviation"data record"Check Lowest"data
    add 1 record"Check Lowest"data index
    end
if record"Potential Chance"layout = number 0
    begin
    put 9999999999 record"Check Lowest"data
    add 1 record"Check Lowest"data index
    end
put 1 record"Check Lowest"data index
put 100% record"Check Lowest"data record"Temp 1"data
add 1 record"Check Lowest"data index
put 100% record"Check Lowest"data record"Temp 2"data
add 1 record"Check Lowest"data index
put 100% record"Check Lowest"data record"Temp 3"data
if record"Temp 1"data < record"Temp 2"data and record"Temp 1"data < record"Temp 3"data and
record"Temp 1"data < record"Expected"data
    begin
    put 1 record"Potential Chance"layout index
    copy record"Potential Chance"layout record"Bet this chance"layout
    end
    else
    begin
    if record"Temp 2"data < record"Temp 1"data and record"Temp 2"data < record"Temp 3"data and
    record"Temp 2"data < record"Expected"data
        begin
        put 2 record"Potential Chance"layout index
        copy record"Potential Chance"layout record"Bet this chance"layout
        end
        else
        begin
        if record"Temp 3"data < record"Temp 1"data and record"Temp 3"data < record"Temp 2"data and
        record"Temp 3"data < record"Expected"data
            begin
            put 3 record"Potential Chance"layout index
            copy record"Potential Chance"layout record"Bet this chance"layout
            end
            else
            begin
            clear record"Potential Chance"layout
            clear record"Check Lowest"data
            exit
            end
        end
    end
set flag "Bet" false
set flag "Put units" true
end

Method "Reset"
begin
put 0 all bets
clear record"Temp 1"data
clear record"Temp 2"data
clear record"Potential Chance"layout
clear record"Check Lowest"data
clear record"Temp 3"data
clear record"Bet this chance"layout
clear record"Unit Size"data
clear record"Bet times"data
clear record"Sub Session Spins"data
reset all flags false
set flag "Bet" true
put 1 record"Sub Session spins"data
end

Method "Track"
begin
put 1 record"EC Layout"layout index
put 1 record"Deviation"data index
track last red-black 37 spibs record"Last RB-"layout
track last odd-even 37 spins record"Last OE-"layout
track last high-low 37 spins record"Last HL-"layout
put 1 record"Last RB-"layout index
put 1 record"Last OE-"layout index
put 1 record"Last HL-"layout index
put 0 record"Red Hit"data
put 0 record"Black Hit"data
put 0 record"High Hit"data
put 0 record"Low Hit"data
put 0 record"Odd Hit"data
put 0 record"Even Hit"data
loop until record"Last RB-"layout index > record"Last RB-"layout count
    begin
    if record"Last RB-"layout = Red
        begin
        add 1 record"Red Hit"data
        end
        else
        begin
        add 1 record"Black Hit"data
        end
    add 1 record"Last RB-"layout index
    end
loop until record"Last OE-"layout index > record"Last OE-"layout count
    begin
    if record"Last OE-"layout = odd
        begin
        add 1 record"Odd Hit"data
        end
        else
        begin
        add 1 record"Even Hit"data
        end
    add 1 record"Last OE-"layout index
    end
loop until record"Last HL-"layout index > record"Last HL-"layout count
    begin
    if record"Last HL-"layout = high
        begin
        add 1 record"High Hit"data
        end
        else
        begin
        add 1 record"Low Hit"data
        end
    add 1 record"Last HL-"layout index
    end
put 100% record"Red Hit"data record"Deviation"data
add 1 record"Deviation"data index
put 100% record"Black Hit"data record"Deviation"data
add 1 record"Deviation"data index
put 100% record"High Hit"data record"Deviation"data
add 1 record"Deviation"data index
put 100% record"Low Hit"data record"Deviation"data
add 1 record"Deviation"data index
put 100% record"Odd Hit"data record"Deviation"data
add 1 record"Deviation"data index
put 100% record"Even Hit"data record"Deviation"data
add 1 record"Deviation"data index
if record"Sub Session Spins"data = 37
    begin
    set flag "Bet" true
    end
end

Method "Init"
begin
put 18 record"Expected"data
load single wheel
copy list [Red, Black, High, Low, Odd, Even] record"EC Layout"layout
while starting a new session
    begin
    put 0 record"Spins"data
    put 0 record"Sub Session Spins"data
    end
exit
end