The Patience System

Contenuto del file

system "The Patience System"
{
 Designed and written by Marcello.
 Enchanced by UX Software.
 
Place bets on 6 numbers based on a particular number that appears.
For example: If number 11,12,13,14,15 or 16 has hit, place bets on numbers
             11,15,17,24,28 and 31.
             
Use this progression after a loss: 1,1,1,1,2,2,2,3,3,4,5,6,7,8,10,12,14,17,21,25,30,
                                   36,43,52,62,75,90,100,100,100,100,100,100,100,100,
                                   100,100,100,100

If after 10 losses in a row, stop placing bets.  Wait until a bet would have won, then
continue at the current progression.  On a win, reset to 1 unit.
}
method "main"  begin
    while starting a new session
    begin
        Group
        begin
            put 10 on record "Total Lost Count" data;
            Display "When there is a certain number of losses in a row,
                     the system will play in Virtual mode and until a Virtual
                     win, then resume at the current or reset progression bet.";
                     
            input data "Enter total loss count in a row" to record "Total Lost Count" data;
            input dropdown "Reset Progression after Virtual mode
                            1:=No
                            2:=Yes" to record "Reset" data;
        end
        
        put 0 on record "Spin Lost Counter" data;
        set list of [1,1,1,1,2,2,2,3,3,4,5,6,7,8,10,12,14,17,21,25,30,36,43,52,
                     62,75,90,100,100,100,100,100,100,100,100,100,100,100,100] to
                      record "Progression"data;


        put 1 on record "Progression" data index;
        put 100% of Bankroll to record "Initial Bankroll" data;
        put 0 on record "Balance"data;
        copy list[number 2,number 10,number 13,number 20,number 26,number 29] to record "1"layout;
        copy list[number 5,number 7,number 14,number 25,number 32,number 36] to record "2"layout;
        copy list[number 11,number 15,number 17,number 24,number 28,number 31] to record "3"layout;
        copy list[number 9,number 12,number 16,number 19,number 30,number 34] to record "4"layout;
        copy list[number 4,number 6,number 8,number 22,number 33,number 35] to record "5"layout
        copy list[number 1,number 3,number 18,number 21,number 23,number 27] to record "6"layout;
        exit
    end


    //add to the LOST Counter here
    add 1 to record "Spin Lost Counter" data;
  
    put 100% of Bankroll to record "Balance" data;
    subtract 100% of record "Initial Bankroll" data from record "Balance" data;

    if record "Balance" data >1 unit then
    begin
        put 1 on record "Progression" data index;
        put 100% of bankroll to record "Initial Bankroll" data;
        put 0 on record "Balance" data;

        //reset spin lost counter, index
        put 0 on record "Spin Lost Counter" data;//reset the LOST counter
        set flag "Virtual" to false;
    end

    if flag "Virtual" is true
    begin
        copy last number to record "Last Number" layout
        
        //if the last number that has HIT is found in the list of Virtual numbers,
        //then turn off virtual
        if record "Last Number" layout is found in record "Virtual numbers" layout
        begin
            set flag "Virtual" to false;
            put 0 on record "Spin Lost Counter" data;//reset the LOST counter
            
            if record "Reset" data = 2
            begin
                put 1 on record "Progression" data index;
            end
        end
    end

    //if we LOST 10 times, go into Virtual mode
    if record "Spin Lost Counter" data = record "Total Lost Count" data
    begin
        set flag "Virtual" to true;
    end

    while number 1  hit each time or  number 2  hit each time
    or    number 3  hit each time or  number 4  hit each time
    or    number 5  hit each time or  number 6  hit each time
    begin
        if flag "Virtual" is false
        begin
            put 100% of record "Progression" data on record "6" layout list;
            add 1 to record "Progression" data index;
        end
        else
        begin
            //Virtual is TRUE. Set Numbers that we would have bet
            //to a Virtual numbers record LIST
            duplicate record "6" to record "Virtual numbers";
        end
    end

    while number 11  hit each time or  number 12  hit each time
    or    number 13  hit each time or  number 14  hit each time
    or    number 15  hit each time or  number 16  hit each time
    begin
        if flag "Virtual" is false
        begin
            put 100% of record "Progression" data on record "3" layout list;
            add 1 to record "Progression" data index;
        end
        else
        begin
            duplicate record "3" to record "Virtual numbers";
        end
    end

    while number 21  hit each time or  number 22  hit each time
    or    number 23  hit each time or  number 24  hit each time
    or    number 25  hit each time or  number 26  hit each time
    or    number 8  hit each time  or  number 18  hit each time
    begin
        if flag "Virtual" is false
        begin
            put 100% of record "Progression" data on record "2" layout list;
            add 1 to record "Progression" data index;
        end
        else
        begin
            duplicate record "2" to record "Virtual numbers";
        end
    end

    while number 31  hit each time or  number 32  hit each time
    or    number 33  hit each time or  number 34  hit each time
    or    number 35  hit each time or  number 36  hit each time
    or    number 28  hit each time
    begin
        if flag "Virtual" is false
        begin
            put 100% of record "Progression" data on record "5" layout list;
            add 1 to record "Progression" data index;
        end
        else
        begin
            duplicate record "5" to record "Virtual numbers";
        end
    end

    while number 10  hit each time or  number 20  hit each time
    or    number 30  hit each time or  number 0  hit each time
    or    number 00  hit each time
    begin
        if flag "Virtual" is false
        begin
            put 100% of record "Progression" data on record "1" layout list;
            add 1 to record "Progression" data index;
        end
        else
        begin
            duplicate record "1" to record "Virtual numbers";
        end
    end

    while number 17  hit each time or  number 27  hit each time
    or    number 9  hit each time or  number 19  hit each time
    or    number 29  hit each time  or  number 7  hit each time
    begin
        if flag "Virtual" is false
        begin
            put 100% of record "Progression" data on record "4" layout list;
            add 1 to record "Progression" data index;
        end
        else
        begin
            duplicate record "4" to record "Virtual numbers";
        end
    end

    //if we reached MAXIMUM progression, RESET back to 1.
    if record "Progression" data index > record "Progression" data count
    begin
        put 1 on record "Progression" data index;
        set flag "Virtual" to false;
        put 0 on record "Spin Lost Counter" data;//reset the LOST counter
    end
end