Pockets and Numbers system

Contenuto del file

system "Pockets_and_Numbers_system"
{
Pockets and Numbers System
see documentation for system explanation

This system uses lots of data recordsto keep track of pockets and numbers

Uses Single Zero Wheel
}
method "main"
begin
    While Starting a New Session
    begin
        Call "Initialize";
        Exit;
    end

    Call "Track Spins";
    Call "Check if initial 37 spins are tracked";
    Call "Check Win";
    
    //If not bets have been placed or we WIN the last bet, then do these routines
    While Flag "Bet Placed" is False
    begin
        Call "Find Pockets";
        Call "Find Numbers that did not hit";
        Call "Find Bracket Numbers that did not appear";
        Call "Find First set to Bet";
    end
    
    //These routines are always perform regardless if we WIN or LOSE
    Call "Find Second set to Bet";
    Call "Place Bets";
end

method "Check Win"
begin
    While Any Number Bet has won each time
    begin
        Set Flag "Bet Placed" to False;
        Call "Reset";
    end
end

//Place a 0 bet on all inside numbers (clears it out)
method "Place Bets"
begin
    Put 0 on All Inside;
    Set Flag "Bet Placed" to True;

    Put 1 on record "First Bet List" layout index;

    Loop until record "First Bet List" layout index >
                record "First Bet List" layout count
    begin
        Add 1 to record "First Bet List" layout;
        Add 1 to record "First Bet List" layout index;
    end
    
    Put 1 on record "Second Bet List" layout index;

    Loop until record "Second Bet List" layout index >
                record "Second Bet List" layout count
    begin
        Add 1 to record "Second Bet List" layout;
        Add 1 to record "Second Bet List" layout index;
    end
end

method "Find Pockets"
begin
    Put 2 on record "Tracked Spins" Layout index;
    Put 2 on record "Tracked Spins" Data index;
    
    Loop until record "Tracked Spins" Layout Index >
                record "Tracked Spins" Layout count
    begin
        Put 0 on Record "Distance between numbers" data;
        Set Flag "Found" to False;
        Call "Get Pockets";
        Put 100 % of Record "Distance between numbers" data on
                                                    Record "Tracked Spins" data;
        Add 1 on Record "Tracked Spins" Data index;
        Add 1 on Record "Tracked Spins" Layout index;
    end
end

method "Get Pockets"
begin
    Subtract 1 from Record "Tracked Spins" Layout index;
    Copy Record "Tracked Spins" layout to record "temp" layout;
    Add 1 to record "Tracked Spins" layout index;
    
    Loop until Flag "Found" is True
    Or  Record "temp" layout = Record "Tracked Spins" layout
    begin
        Locate Number Left the total of Record "Distance between numbers" data
              gaps from Record "temp" layout into Record "temp 2" layout;

        While Record "temp 2" layout = Record "Tracked Spins" layout
        begin
            Set Flag "Found" to True;
        end

        Add 1 on Record "Distance between numbers" data;
    end
end

//Points to the list of all 37 numbers on the wheel
method "Find Numbers that did not hit"
begin
    Clear record "Numbers with No Hits" layout;
    put 1 on record "Numbers with No Hits" layout index;
    Put 1 on record "Single wheel" layout index;

    Loop until record "Single wheel" Layout Index >
                record "Single wheel" Layout count
    begin
        Call "Find a match in wheel";
        Add 1 on Record "Single wheel" layout index;
    end
end

//Performs a comparison and finds a match
method "Find a match in wheel"
begin
    Put 1 on record "Tracked Spins" Layout index;

    Loop until record "Tracked Spins" Layout Index >
                record "Tracked Spins" Layout count
    begin
        If Record "Single wheel" layout = Record "Tracked Spins" layout
        begin
            Return;
        end

        Add 1  on Record "Tracked Spins" layout index;
    end
    
   //No match, then Number did not hit so move it to the No Hits list
    Copy record "Single wheel" layout to record "Numbers with No Hits" layout;
    Add 1 to record "Numbers with No Hits" layout index;
end

//Points to the list of all 37 numbers on the wheel
method "Find Bracket Numbers that did not appear"
begin
    Clear record "Brackets with No Hits" layout;
    put 1 on record "Brackets with No Hits" layout index;
    Put 0 on record "Number" data;
    
    Loop until record "Number" Data > 36
    begin
        Call "Find a bracket in wheel";
        Add 1 on Record "Number" data;
    end
end

//Performs a comparison and finds a match
method "Find a bracket in wheel"
begin
    Put 1 on record "Tracked Spins" Data index;

    Loop until record "Tracked Spins" Data index >
                record "Tracked Spins" Data count
    begin
        If Record "Number" Data = Record "Tracked Spins" Data
        begin
            Return;
        end

        Add 1 on Record "Tracked Spins" Data index;
    end

    //No match, then Bracket Number did not hit so move it to the Bracket No Hits list
    //Reference the Bracke Number to the Actual Number on the Single Wheel
    Put 100% of record "Number" data to record "Single wheel" Layout index;
    //Adjust wheel pointer.
    Add 1 to record "Single wheel" layout index;
    //Copy the Number from the wheel to the Bracket No Hits list
    Copy record "Single wheel" layout to record "Brackets with No Hits" layout;
    Add 1 to record "Brackets with No Hits" layout index;
end

method "Find First set to Bet"
begin
    Clear record "First Bet List" layout;
    Put 1 on record "Numbers with No Hits" layout index;

    Loop until record "Numbers with No Hits" layout index >
                record "Numbers with No Hits" layout count
    begin
        put 1 on record "Brackets with No Hits" layout index;
        
        Loop until record "Brackets with No Hits" layout index >
                                record "Brackets with No Hits" layout count
        begin
            if record "Numbers with No Hits" layout =
                                                    record "Brackets with No Hits" layout
            begin
                Copy record "Numbers with No Hits" layout to
                        record "First Bet List" layout;
                Add 1 to record "First Bet List" layout index;
            end
            
            Add 1 to record "Brackets with No Hits" layout index;
        end
        
        Add 1 to record "Numbers with No Hits" layout index;
    end
end

method "Find Second set to Bet"
begin
    Clear record "Second Bet List" layout;
    Set Max to record "Tracked Spins" Layout index;
    Put 1 on record "First Bet List" layout index;

    Loop until record "First Bet List" layout index >
                record "First Bet List" layout count
    begin
        Call "Convert layout Number to data Number";

        if record "Distance between numbers" data >=0 then
        begin
            Locate Number Left the total of Record "Distance between numbers" data gaps
                from Record "Tracked Spins" layout into Record "Second Bet List" layout;
        end
        else
        begin
            Copy record  on "Tracked Spins" layout to record "Second Bet List" layout;
        end

        Add 1 to record "Second Bet List" layout index;
        Add 1 to record "First Bet List" layout index;
    end
end

method "Convert layout Number to data Number"
begin
    Put 1 on record "Single wheel" layout index;
    
    Loop until record "Single wheel" layout index > record "Single wheel" layout count
    begin
        if record "First Bet List" layout = record "Single wheel" layout
        begin
            Put 100% of record "Single wheel" Layout index to
                                                  record "Distance between numbers" data;
            Subtract 2 from record "Distance between numbers" data;
            Return;
        end
        
        Add 1 to record "Single wheel" layout index;
    end
end
    
method "Check if initial 37 spins are tracked"
begin
    While Record "Tracked Spins" Layout count < 37
    begin
        Exit;
    end
end

method "Track Spins"
begin
    Set Max to record "Tracked Spins" Layout index;
    Add 1  on Record "Tracked Spins" Layout index;
    Copy last Number to the Record "Tracked Spins" layout;

    if record "Tracked Spins" Layout index > 37 then
    begin
        Move List Up by 1 on record "Tracked Spins" Layout;
        Set Max to record "Tracked Spins" Layout index;
    end
end

method "Initialize"
begin
    Set Flag "Bet Placed" to false;
    Set Flag "Found" to false;
    Set Flag "Matched" to false;
    Load Single Wheel;
    Clear Record "Distance between numbers" data;
    Clear Record "Number to determine pockets" data;
    Clear Record "Number to find pockets" data;

    Clear Record "Tracked Spins" data;

    Copy list [Number 0, Number 1, Number 2, Number 3, Number 4,
               Number 5, Number 6, Number 7, Number 8, Number 9,
               Number 10,Number 11,Number 12,Number 13,Number 14,
               Number 15,Number 16,Number 17,Number 18,Number 19,
               Number 20,Number 21,Number 22,Number 23,Number 24,
               Number 25,Number 26,Number 27,Number 28,Number 29,
               Number 30,Number 31,Number 32,Number 33,Number 34,
               Number 35,Number 36] to Record "Single wheel" layout;

    Clear Record "Numbers with No Hits" layout;
    Clear Record "Brackets with No Hits" layout;
    Clear Record "First Bet List" layout;
    Clear Record "Second Bet List" layout;

    Clear Record "Track last 37 numbers" data;
    Clear Record "Total Numbers that did not hit" data;
    Clear Record "Total Bracket Numbers that did not appear" data;
    Clear Record "Total First set of numbers to Bet" data;
    Clear Record "Total Second set of numbers to bet" data;
    Clear Record "List of 37 numbers (Single Zero wheel)" data;


    Call "Reset";
end

method "Reset"
begin
    Clear record "Tracked Spins" data;
    Clear Record "Numbers with No Hits" layout;
    Clear Record "Brackets with No Hits" layout;
    Clear Record "First Bet List" layout;
    Clear Record "Second Bet List" layout;
end