Midas Touch System

Contenuto del file

system "Midas_Touch_System"

{The Midas Touch system is a cross-out system similar to the Labouchere
It begins with with a list of 4 numbers derived from a stated win goal.
The first number is 40% of the win goal and the remaining 3 numbers
are 20% each.  It will ask you to enter your bet layout.
When first starting out or after any loss, the next bet is determined by the
amount of the first (uncrossed) number in the list.  (Note: this bet file
removes crossed out numbers from the list, but if you were playing with pen
paper you would probably be crossing them off.
Whenever you win, the numbers used to determine the bet are crossed off
the list (which could be either the 1st or the 1st and last numbers)  and the
the next bet is determined by adding the new 1st and last (uncrossed)
numbers in the list.
Whenever you lose, the amount lost is added to the end of the list.

Taken from Win Craps system
}
method "main"
begin
    While Starting a New Session
    begin
        Clear All Records;
        Clear Record "Reference used for swapping Stores" data;
        Clear Record "Win goal" data;
        Clear Record "Number of winning games" data;
        Clear Record "Bet list" data;
        Set Flag "Used 2 numbers to determine bet" to false;
        Set Flag "Layout win flag" to false;
        call "Input Layout";
        call "Reset";
        call "Figure and make next bet";
        exit;
    end

    //Add any loss to the end of the list
    While Record "Current Layout to Bet" layout has lost each time
    begin
        Set Flag "Layout win flag" to False;
        set max on record "Bet list" data index;
        Add 1 on Record "Bet list" Data index;
        Put 100% of the last Record "Current Layout to Bet" Layout to
                                                        Record "Bet list" data;
        call "Figure and make next bet";
        exit;
    end
    
    While Record "Current Layout to Bet" layout has won each time
    begin
        Set Flag "Layout win flag" to True;
        call "Cross off winning numbers";
        call "Figure and make next bet";
    end
end

method "Cross off winning numbers"
begin
    //Move list down for crossed off numbers
    Put 1 on record "Bet list" data index;

    While Flag "Used 2 numbers to determine bet" is True
    begin
        Move List Down by 1 on record "Bet list" data;
        move list up by 1 on record "Bet list" data;
    end

    if record "Bet list" data count>0
    begin
        move list up by 1 on record "Bet list" data;
    end

    //Check progression
    While Record "Bet list" Data count = 0
    begin
        Display "The progression has won and will 
                  start over now.";
        Add 1  on Record "Number of winning games" data;
        call "Reset";
        call "Figure and make next bet";
        exit;
    end
end

method "Figure and make next bet"
begin
    put 1 on record "Bet list" data index;
    Put 100 % of Record "Bet list" data on Record "Current Layout to Bet" layout;
    Set Flag "Used 2 numbers to determine bet" to False;
    
    While Flag "Layout win flag" is True
    And  Record "Bet list" Data count > 1
    begin
        set max on record "Bet list" data index;
        Add 100% of Record "Bet list" data on
                                          Record "Current Layout to Bet" layout;
        Set Flag "Used 2 numbers to determine bet" to True;
    end
end

method "Reset"
begin
    put 1 on record "Bet list" data index;
    Put 40 % of Record "Win goal" data on Record "Bet list" data;
    add 1 to record "Bet list" data index;
    Put 20 % of Record "Win goal" data on Record "Bet list" data;
    add 1 to record "Bet list" data index;
    Put 20 % of Record "Win goal" data on Record "Bet list" data;
    add 1 to record "Bet list" data index;
    Put 20 % of Record "Win goal" data on Record "Bet list" data;
    put 1 on record "Bet list" data index;
    Set Flag "Layout win flag" to False;
end

method "Input Layout"
begin
    Group
    begin
        Input Dropdown "Make a Layout Selection

                  1:=Even
                  2:=Odd
                  3:=Red
                  4:=Black
                  5:=High (19-36)
                  6:=Low (1-18)" to Record "Layout number" data;
        Input Data "How much would you like to set
                  as your win goal?" to Record "Win goal" data;
    end
    
    Call "Setup Layout";
end

method "Setup Layout"
begin
    While Record "Layout number" data = 1
    begin
        Copy Even to the Record "Current Layout to Bet" layout;
    end
    Else
    begin
        While Record "Layout number" data = 2
        begin
            Copy Odd to the Record "Current Layout to Bet" layout;
        end
        Else
        begin
            While Record "Layout number" data = 3
            begin
                Copy Red to the Record "Current Layout to Bet" layout;
            end
            Else
            begin
                While Record "Layout number" data = 4
                begin
                    Copy Black to the Record "Current Layout to Bet" layout;
                end
                Else
                begin
                    While Record "Layout number" data = 5
                    begin
                        Copy high to the Record "Current Layout to Bet" layout;
                    end
                    Else
                    begin
                        While Record "Layout number" data = 6
                        begin
                            Copy low to the Record "Current Layout to Bet" layout;
                        end
                    end
                end
            end
        end
    end
end