Labouchere Progression

Contenuto del file

system "Labouchere_System"

{The Labourchere is a cross-out system which begins with a list containing an
arbitrary sequence of numbers such as 1,2,3,4.
The next bet is determined by adding the first and last numbers in the list.
When the bet wins, the first and last numbers are crossed-out (zeroed out for the
System's purpose). When the bet loses, the lost amount is added to the end
of the list.
}
method "main"
begin
    While Starting a New Session
    begin
        Clear record "Progression list" data;
        Clear record "Pointer" data;
        call "Reset";
        call "Figure and make next bet";
        exit;
    end
    
    While Black has won each time
    begin
        Put 1 on record "Progression list" Data index;
        Put 0 on record "Progression list" data;
        put 100% of record "Pointer" data to
                        record "Progression list" data index;
        Put 0 on record "Progression list" data;
    end
    
    While Black has lost each time
    begin
        Add 1 on record "Pointer" data;
        put 100% of record "Pointer" data to
                        record "Progression list" data index;
        Put 100 % of the last Black on record "Progression list" data;
    end
    
    Put 1 on record "Progression list" Data index;

    If record "Progression list" data = 0
    begin
        Move List Up by 1 to Record "Progression list" Data;
        Subtract 2 from Record "Pointer" Data;
        Put 1 on record "Progression list" Data index;
    end

    If record "Progression list" data = 0
    begin
        //Progression has won. Start Over
        call "Reset";
    end

    call "Figure and make next bet";
end

method "Reset"
begin
    Set List [1,2,3,4] on record "Progression list" data;
    Put 4 on record "Pointer" data;
    Put 1 on record "Progression list" Data index;
end

method "Figure and make next bet"
begin
    Put 1 on record "Progression list" Data index;
    Put 100 % of record "Progression list" data on Black;
    
    While Record "Pointer" data > 1
    begin
        put 100% of record "Pointer" data to
                        record "Progression list" data index;
        Add 100 % of record "Progression list" data on Black;
    end
end