Drop3

Contenuto del file

system "Drop 3"

{
  Vedere lo scarto tra gli ultimi 12 manque e Passe
  Se � maggiore o minore di 6 si gioca fino a che lo scarto arriva a zero
  spiegazione completa su www.laroulette.it
  Sistema di: Varan
  Xtremizzato da: lonerider

}
method "main"
begin     // inizializza i parametri
    While Starting a New Session
    begin
	   set Flag "Gioca" to false;
       Put 1 record "progressione" Data
     end

    While On each Spin  // Ad ogni boule
    begin
        If flag "Gioca" true   // controlla se si � giocato
        begin
            call "Risultati"  // e manda al record risultati
        end
        // Memorizza gli ultimi 12 manque o passe nel record Ultimi12
        Track last  High-Low 12 record "Ultimi12" layout

        Call "Verifica"; // va alla routine di controllo

        If flag "Gioca" true  // se il gioco � attivo
        begin //Punta la chance selezionata secondo la progressione
            put 100% record "Progressione" data Record "DaPuntare" Layout list
        end

    end
end


method "Verifica" // verifica del momento di attacco
begin
    //se ce ne sono meno di 12 torna indietro
    If record "Ultimi12" Layout count <12
    begin
        return
    end
    //Azzera le variabili
    Clear record "KManque" data
    Clear record "KPasse" data
    Clear record "Scarto_MP" data
    // Fa passare in ciclo tutti le 12 chance
    put 1 record "Ultimi12" Layout index
    loop until record "Ultimi12" Layout index > record "Ultimi12" Layout count
    begin
        If record "Ultimi12" Layout = High  // Se � passe
        begin
            Add 1 record "KPasse" data   //Aumenta di 1 il contatore dei passe
        end
        If record "Ultimi12" Layout = Low  // Se � manque
        begin
            Add 1 record "KManque" data  //Aumenta di 1 il contatore dei manque
        end
        add 1 record "Ultimi12" Layout index
    end
    //Calcola lo scarto tra le due chance
    Put 100 % record "KManque" data record "Scarto_MP" data
    subtract 100% record "KPasse" data record "Scarto_MP" data
    //Controlla se si sta puntando
    If flag "Gioca" True
    begin
        if Record "Scarto_MP" Data =0  //Se lo scarto arriva a 0 finisce l'attacco
        begin
            Set flag "Gioca" False     //Si smette di giocare
            Put 1 record "progressione" Data //Si rimette la progressione a 1
        end
    end
    // Controlla se lo scarto � arrivato a 6
    if flag "Gioca" false
    begin
        If record "Scarto_MP" data >=6 //Pi� manque che passe
        begin
            Set flag "Gioca" true // Attiva la giocata
            Copy high record "DaPuntare" layout // assegna Passe da puntare
        end
        If record "Scarto_MP" data <=-6  //Pi� passe che manque
        begin
            Set flag "Gioca" true // Attiva la giocata
            Copy low record "DaPuntare" layout // assegna manque da puntare
        end
    end
 end

method "Risultati"
begin
    If Any High-Low Bet won each  //Controlla se ha vinto
    begin
        subtract 1 record "progressione" data //Abbassa di 1 la progressione
        if record "progressione" Data = 0 //Se � gi� a 1 la lascia a 1
        begin
            put 1 record "progressione" Data
        end
    end
    If Any High-Low Bet lost each //Aumenta di 1 la progressione
    begin
        add 1 record "progressione" data
    end

end