Metodo ing. HansB.

Contenuto del file

system "Hans B - Original"
{ sistema scritto nel libro di L.Groass
	Si segnano tutti i pieni e si cominciano a giocare non appena uno esce una volta.
	mentre si continuano a segnare i numeri usciti si gioca fincheè non esce.
	Quando esce si torna alla boule dell'inizio della giocata e si cerca il primo uscito solo una volta.
	Quello idventail nuovo numero e si va avanti così fino aal fine e cioè quando non ci sono più boules da giocare
	
	Metodo da usare.
	Memorizzare i numeri pieni per contare quante volte sono usciti.
	memorizzare le boules ed i numeri
	Ad ogni verifica creareun record con solo i numeri usciti una volta e poi usarlo
	per cercare il primo partendo dalla boule e per verificare che sono usciti tutti.
}
method "main"
begin
    While Starting new Session
    begin
        //Inizializza variabili
		copy list [Number 1,Number 2,Number 3,Number 4,Number 5,Number 6,Number 7,Number 8,Number 9,
			Number 10,Number 11,Number 12,Number 13,Number 14,Number 15,Number 16,Number 17,Number 18,
			Number 19,Number 20,Number 21,Number 22,Number 23,Number 24,Number 25,Number 26,Number 27,
			Number 28,Number 29,Number 30,Number 31,Number 32,Number 33,Number 34,Number 35,Number 36,
			Number 0]nel  Record "Pieni" layout
		set list [1,36,53,65,73,80,86,91,95,99,102,105,108,110,113,115,117,119,121,123,125,126,128,129,131,132,133,
				  135,136,137,138,139,140,141,142,143,144,145,146,147,148,149,150,151,152,153,154,155] record "StepProgressione" data
		set flag "Gioca" false
		put 1 record "InizioGioco" Data
    end
    
    While On each Spin
    begin 
        add 1 record "Boules" layout index
        copy last Number nel record "Boules" Layout // memorizza il numero uscito nel record Boules
 		put 1 Record "Pieni" Layout index
		loop until Record "Pieni" Layout index > Record"Pieni" Layout count
  		begin  // aumenta di 1 il contatore del numero uscito
      		if record "Boules" Layout = Record "Pieni" Layout
      		begin
      			Put 100% Record "Pieni" Layout index nel Record "Conta_Usciti" data index
      			Add 1 Record "Conta_Usciti" data
      		end
      		add 1 Record "Pieni" Layout index
  		end     
		if record "Boules" Layout = Record "DaPuntare" Layout // verifica se il numero uscito ha vinto
		begin
			set flag "Gioca" False
		end
		
		If flag "Gioca" false
		begin
			Call "Verifica"
		end
		If flag "Gioca" true
		begin
			Call "Punta"
			//Call "Punta mp"
		end

    end
end
method "Verifica"
begin
    // Mette tutti quelli da 1 nel record temp
	clear Record "temp" data
    duplicate record "Conta_Usciti" nel Record "TempUsciti"
	put 1 Record "TempUsciti" Data index
	loop until Record "TempUsciti" Data index > Record "TempUsciti" Data count
  	begin
      	if Record "TempUsciti" Data = 1
      	begin
			add 1 record "temp" data index
			put 100% Record "TempUsciti" Data index nel record "temp" data
      	end
      	add 1 Record "TempUsciti" Data index
	end
	
	If record "temp" Data count =0 //verfica che non ci siano più numeri con 1 sola uscita
	begin
		//Stop Session  //da aggiungere o mettere a seconda dell'analisi che si vuol fare, partita singola o continuo
		Call "Reset"
	end
	
	// adesso partendo dalla boule di inizio gioco controlla se il numero è uscito 1 volta
	// e diventa il nuovo numero da giocare
	Duplicate record "Boules" nel record "TempBoules"
	Put 100% record "InizioGioco" data nel record "TempBoules" layout index
		loop until record "TempBoules" layout index > record "TempBoules" Layout count
 		begin
			Put 1 Record "Temp" Data index
			loop until record "Temp" Data index > record "Temp" Data count
  			begin
    			put 100% Record "Temp" Data nel record "Pieni" layout index
				If record "TempBoules" layout = Record "Pieni" Layout
    			Begin
    				Put 100% record "TempBoules" layout index nel record "InizioGioco" data
    				Copy  record "Pieni" layout nel record "DaPuntare" layout
    				Set flag "Gioca" true //attiva la giocata
    				put 0 record "contacolpi" data //resetta le puntate
    				put 1 record "StepProgressione" data index
    				return
    			end
				add 1 Record "Temp" Data index
			end
			add 1 Record "TempBoules" layout index  
  		end     

end  
method "punta"
begin // controlla se il numero di puntate effettuate è uguale al termine successivo della progressione
	  //ed assegna un nuovo numero di pezzi
    if record "StepProgressione" data index > record "StepProgressione" data count
    begin
    	return
    end
	Add 1 record "contacolpi" data
	if record "contacolpi" data = record "StepProgressione" data
    begin
    	put 100% record "StepProgressione" data index nel record "pezzi" data
    	add 1 record "StepProgressione" data index
    end
	put 100%  record "pezzi" data nel record  "DaPuntare"  Layout

end
method "punta mp" //versione a massa pari che si ferma al 36esimo colpo
begin
	Add 1 record "contacolpi" data
	put 1 nel record "pezzi" data
	if record "contacolpi" data >= 36
    begin
    	put 0 nel record "pezzi" data
    end
	put 100%  record "pezzi" data nel record  "DaPuntare"  Layout

end
method "Reset"  // riazzera le puntate quando non ci sono più numeri con 1 sola uscita.
begin
	clear All Records Except ["Pieni"] Layout
	clear All Records Except ["StepProgressione"] data
	set flag "Gioca" false
	put 1 record "InizioGioco" Data
		
    



end