Against all odds v2

Contenuto del file

system "Against all odds version2"
{
Created by TurboGenius

for documentation visit: http://gambling.projectsydney.com/viewtopic.php?t=478
}
method "main"
begin
while starting a new session
    begin
    call "initialize";
    call "input";
    call "reset";
    exit;
    end

if Any Inside Bet has won each time
or Any Outside Bet has won each time
    begin
    call "reset";
    call "check profit";
    end


if number 0 has hit each time or number 00 has hit each time
    begin
    exit;
    end
call "track last number, split, street, corner, line, dozen, EM"

if flag "location set" is false
    begin
    call "move to next location";
    end

if record "location index" data = 1 //even
    begin
    call "do even bet";
    end

if record "location index" data = 2 //dozen
    begin
    call "do dozen bet";
    end

if record "location index" data = 3 //line (lanes)
    begin
    call "do line bet";
    end

if record "location index" data = 4 //corner (squares)
    begin
    call "do corner bet";
    end

if record "location index" data = 5 //street
begin
call "do street bet";
end

if record "location index" data = 6 //splits
    begin
    call "do split bet";
    end

if record "location index" data = record "max location index" data //straight
    begin
    call "do straight bet";
    end

//check if we exceeded max location index
if record "location index" data > record "max location index" data
    begin
    call "reset";
    //start at the beginning.
    put 100% Bankroll to record "current bankroll" data;
    put 0 on record "location index" data;
    call "move to next location";
    call "do even bet";
    end
end

method "check profit"
begin
put 100% of Bankroll to record "profit" data;
subtract 100% of record "current bankroll" data to record "profit" data;

if record "profit" data > 0 then
    begin
    put 0 on record "location index" data;
    end
    else
    begin
    subtract 2 to record "location index" data;
    if record "location index" data < 0 then
        begin
        put 0 on record "location index" data;
        end
    end
end

method "move to next location"
begin
set flag "location set" to false;



add 1 to record "location index" data;
set flag "location set" to true;
end


method "do straight bet" //straight up
begin
if record "straight bet" data index > record "straight bet" data count
    begin
    add 1 to record "location index" data;
    return;
    end
put 100% of record "straight bet" data to record "last spin" layout;
add 1 to record "straight bet" data index;
exit;
end


method "do split bet" //Split bet
begin
if record "split bet" data index > record "split bet" data count
    begin
    call "move to next location";
    return;
    end
if record "split bet" data index <= 1
begin
if record"hot or sleeper"data = 1
    begin //hot
    call "select 'hottest' split type"
    end
    else
    begin //sleeper
    call "select 'coldest' split type"
    end
end
if flag "no split type" is false
    begin
    put 100% of record "split bet" data to record "split" layout;
    add 1 to record "split bet" data index;
    end
exit;
end

method "do street bet" //Street bet
begin
if record "street bet" data index > record "street bet" data count
    begin
    call "move to next location";
    return;
    end
if record "street bet" data index <= 1
begin
if record"hot or sleeper"data = 1
    begin //hot
    call "select 'hottest' street type"
    end
    else
    begin //sleeper
    call "select 'coldest' street type"
    end
end
if flag "no street type" is false
    begin
    put 100% of record "street bet" data to record "street" layout;
    add 1 to record "street bet" data index;
    end
exit;
end

method "do corner bet" //Corner bet
begin
if record "corner bet" data index > record "corner bet" data count
    begin
    call "move to next location";
    return;
    end
if record "corner bet" data index <= 1
begin
if record"hot or sleeper"data = 1
    begin //hot
    call "select 'hottest' corner type"
    end
    else
    begin //sleeper
    call "select 'coldest' corner type"
    end
end
if flag "no corner type" is false
    begin
    put 100% of record "corner bet" data to record "corner" layout;
    add 1 to record "corner bet" data index;
    end
exit;
end

method "do line bet" //Line bet
begin
    if record "line bet" data index > record "line bet" data count
    begin
    call "move to next location";
    return;
    end
if record "line bet" data index <= 1
begin
if record"hot or sleeper"data = 1
    begin //hot
    call "select 'hottest' line type"
    end
    else
    begin //sleeper
    call "select 'coldest' line type"
    end
end
if flag "no line type" is false
    begin
    put 100% of record "line bet" data to record "line" layout;
    add 1 to record "line bet" data index;
    end
exit;
end

method "do dozen bet" // Dozen bet
begin
    if record "dozen bet" data index > record "dozen bet" data count
    begin
    call "move to next location";
    return;
    end
if record "dozen bet" data index <= 1
begin
if record"hot or sleeper"data = 1
    begin //hot
    call "select 'hottest' Dozen type"
    end
    else
    begin //sleeper
    call "select 'coldest' Dozen type"
    end
end
if flag "no dozen type" is false
    begin
    put 100% of record "dozen bet" data to record "dozen" layout;
    add 1 to record "dozen bet" data index;
    end
exit;
end

method "do even bet" // Even Money Bet
begin
if record "even bet" data index > record "even bet" data count
    begin
    call "move to next location";
    return;
    end
if record "even bet" data index <= 1
begin
if record"hot or sleeper"data = 1
    begin //hot
    call "select 'hottest' EM type"
    end
    else
    begin //sleeper
    call "select 'coldest' EM type"
    end
end
if flag "no even money type" is false
    begin
    put 100% of record "even bet" data to record "even money" layout;
    add 1 to record "even bet" data index;
    end
exit;
end

method "input"
begin
group
    begin
    display "Turbo's Against All Odds system";
    input data "Enter starting Bankroll" to record "current bankroll" data;
    input dropdown "Table type
    1:=Single Zero
    2:=Double Zero" to record "table index" data;
    input dropdown "Play selection
    1:= Play the locations that have shown the most (Hot)
    2:= Play the locations that have shown the least (Sleepers)"
    to record"hot or sleeper"data
    input dropdown "Reset selection
    1:= reset running totals of each location after a win
    2:= don't reset running totals of each location after a win"
    to record"reset running total"data
    end

put 2 on record "prog. index" data;
call "set bet progression";

put 100% of record "current bankroll" data to Bankroll;

if record "table index" data = 1 then
    begin
    load single wheel;
    end
    else
    begin
    load double wheel;
    end
end

method "initialize"
begin
clear record "last spin" layout;
clear record "even money" layout;
put 0 on record "location index" data;

put 100% of bankroll to record "current bankroll" data;
put 0 to record "profit" data;

set list [1,3,6,12,21,33,52,90] to record "index" data;

copy list [red,black,high,low,even,odd] to record"even money types"layout
set list [0,0,0,0,0,0] to record"even money frequency"data
copy list [1st dozen, 2nd dozen, 3rd dozen] to record"dozen types"layout
set list [0,0,0] to record"dozen frequency"data
copy list [number 1, number 2, number 3,number 4,number 5,number 6,
number 7,number 8,number 9,number 10,number 11,number 12,number 13,number 14,
number 15,number 16,number 17,number 18,number 19,number 20,number 21,number 22,
number 23,number 24,number 25,number 26,number 27,number 28,number 29,number 30,
number 31,number 32,number 33,number 34,number 35,number 36] to record"number types"layout
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] to
record"number frequency"data
copy list [Line(1-6),Line(7-12),Line(13-18),Line(19-24),Line(25-30),Line(31-36)]
to record"line types"layout
set list [0,0,0,0,0,0] to record"line frequency"data
set list [1,1,1,1,1,1,2,2,2,2,2,2,3,3,3,3,3,3,4,4,4,4,4,4,5,5,5,5,5,5,6,6,6,6,6,6]
to record"line number"data
copy list [Corner(1:5),Corner(2:6),Corner(4:8),Corner(5:9),Corner(7:11),
Corner(8:12),Corner(10:14),Corner(11:15),Corner(13:17),Corner(14:18),Corner(16:20),
Corner(17:21),Corner(19:23),Corner(20:24),Corner(22:26),Corner(23:27),Corner(25:29),
Corner(26:30),Corner(28:32),Corner(29:33),Corner(31:35),Corner(32:36)]
to record"corner types"layout
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] to record"corner frequency"data
set list [1,2,4,5,7,8,10,11,13,14,16,17,19,20,22,23,25,26,28,29,31,32] to record"c1"data
set list [2,3,5,6,8,9,11,12,14,15,17,18,20,21,23,24,26,27,29,30,32,33] to record"c2"data
set list [4,5,7,8,10,11,13,14,16,17,19,20,22,23,25,26,28,29,31,32,34,35] to record"c3"data
set list [5,6,8,9,11,12,14,15,17,18,20,21,23,24,26,27,29,30,32,33,35,36] to record"c4"data
copy list [Street(1-3),Street(4-6),Street(7-9),Street(10-12),Street(13-15),
Street(16-18),Street(19-21),Street(22-24),Street(25-27),Street(28-30),Street(31-33),
Street(34-36)] to record"street types"layout
set list [0,0,0,0,0,0,0,0,0,0,0,0] to record"street frequency"data
copy list [Split(1-4),Split(2-5),Split(3-6),Split(7-10),Split(8-11),Split(9-12),
Split(13-16),Split(14-17),Split(15-18),Split(19-22),Split(20-23),Split(21-24),
Split(25-28),Split(26-29),Split(27-30),Split(31-34),Split(32-35),Split(33-36)]
to record"split types"layout
set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] to record"split frequency"data
set list [1,2,3,7,8,9,13,14,15,19,20,21,25,26,27,31,32,33] to record"s1"data
set list [4,5,6,10,11,12,16,17,18,22,23,24,28,29,30,34,35,36] to record"s2"data
end

method "reset"
begin
put 1 on record "even bet" data index;
put 1 on record "dozen bet" data index;
put 1 on record "line bet" data index;
put 1 on record "corner bet" data index;
put 1 on record "street bet" data index;
put 1 on record "split bet" data index;
set flag "location set" to false;
if record"reset running total"data = 1
    begin
    set list [0,0,0,0,0,0] to record"even money frequency"data
    set list [0,0,0] to record"dozen frequency"data
    set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] to
    record"number frequency"data
    set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] to record"corner frequency"data
    set list [0,0,0,0,0,0,0,0,0,0,0,0] to record"street frequency"data
    set list [0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0] to record"split frequency"data
    end
end

method "set bet progression"
begin
//aggressive mode
put 6 on record "max location index" data;
set list [5,5] to record "even bet" data;
set list [5,8,12] to record "dozen bet" data;
set list [7,9,11,13,15,18] to record "line bet" data;
set list [14,16,18,20,22,25,28,32,36] to record "corner bet" data;
set list [29,32,35,38,42,45,50,54,59,64,70,77] to record "street bet" data;
set list [54,57,61,64,68,72,76,81,86,91,96,102,108,114,121,128,135,143]
to record "split bet" data;
end

method "track last number, split, street, corner, line, dozen, EM"
begin
//Even Money Bets
track last black-red for 1 time in record"last EM"layout
call "update EM frequencies"
track last high-low for 1 time in record"last EM"layout
call "update EM frequencies"
track last even-odd for 1 time in record"last EM"layout
call "update EM frequencies"
//Dozens
track last dozen for 1 time in record"last dozen"layout
call "update dozen frequencies"
//Numbers (needed for lines, corners and splits calculations)
track last number for 1 time in record"last number"layout
call "update number frequencies"
//Lines
call "update line frequencies"
//Corners
call "update corner frequencies"
//Streets
track last street for 1 time in record"last street"layout
call "update street frequencies"
//Splits
call "update split frequencies"
end

method "select 'hottest' EM type"
begin
// select "hottest" even money type
put 1 in record"even money frequency"data index
put 0 in record"temp"data
loop until record"even money frequency"data index > record"even money frequency"data count
    begin
    if record"even money frequency"data > record"temp"data
        begin
        put 100% of record"even money frequency"data in record"temp"data
        put 100% of record"even money frequency"data index in record"even money types"layout index
        copy record"even money types"layout in record "even money" layout
        end
    add 1 in record"even money frequency"data index
    end
// check if "hottest" even money type is the only coldest one
call "check for lonely even money type"
end

method "select 'coldest' EM type"
begin
// select "coldest" even money type
put 1 in record"even money frequency"data index
put 999999 in record"temp"data
loop until record"even money frequency"data index > record"even money frequency"data count
    begin
    if record"even money frequency"data < record"temp"data
        begin
        put 100% of record"even money frequency"data in record"temp"data
        put 100% of record"even money frequency"data index in record"even money types"layout index
        copy record"even money types"layout in record "even money" layout
        end
    add 1 in record"even money frequency"data index
    end
// check if "coldest" even money type is the only hottest one
call "check for lonely even money type"
end

method "check for lonely even money type"
begin
put 0 in record"alone"data
set flag "no even money type" to false
put 1 in record"even money frequency"data index
loop until record"even money frequency"data index > record"even money frequency"data count
    begin
    if record"even money frequency"data = record"temp"data
        begin
        add 1 in record"alone"data
        end
    add 1 in record"even money frequency"data index
    end
If record"alone"data > 1
    begin
    set flag "no even money type" to true
    end
end

method "update EM frequencies"
begin
put 1 in record"even money types"layout index
loop until record"even money types"layout = record"last EM"layout
    begin
    add 1 in record"even money types"layout index
    end
put 100% of record"even money types"layout index in record"even money frequency"data index
add 1 to record"even money frequency"data
end

method "update dozen frequencies"
begin
put 1 in record"dozen types"layout index
loop until record"dozen types"layout = record"last dozen"layout
    begin
    add 1 in record"dozen types"layout index
    end
put 100% of record"dozen types"layout index in record"dozen frequency"data index
add 1 to record"dozen frequency"data
end

method "update number frequencies"
begin
//translate last number spon to decimal number
put 1 in record"last number decimal"data
put 1 in record"number types"layout index
loop until record"number types"layout = record"last number"layout
    begin
    add 1 in record"number types"layout index
    add 1 in record"last number decimal"data
    end
put 100% of record"number types"layout index in record"number frequency"data index
add 1 to record"number frequency"data
end

method "select 'hottest' Dozen type"
begin
// select "hottest" dozen type
put 1 in record"dozen frequency"data index
put 0 in record"temp"data
loop until record"dozen frequency"data index > record"dozen frequency"data count
    begin
    if record"dozen frequency"data > record"temp"data
        begin
        put 100% of record"dozen frequency"data in record"temp"data
        put 100% of record"dozen frequency"data index in record"dozen types"layout index
        copy record"dozen types"layout in record "dozen" layout
        end
    add 1 in record"dozen frequency"data index
    end
// check if "hottest" dozen type is the only coldest one
call "check for lonely dozen type"
end

method "select 'coldest' Dozen type"
begin
// select "coldest" dozen type
put 1 in record"dozen frequency"data index
put 999999 in record"temp"data
loop until record"dozen frequency"data index > record"dozen frequency"data count
    begin
    if record"dozen frequency"data < record"temp"data
        begin
        put 100% of record"dozen frequency"data in record"temp"data
        put 100% of record"dozen frequency"data index in record"dozen types"layout index
        copy record"dozen types"layout in record "dozen" layout
        end
    add 1 in record"dozen frequency"data index
    end
// check if "coldest" dozen type is the only hottest one
call "check for lonely dozen type"
end

method "check for lonely dozen type"
begin
put 0 in record"alone"data
set flag "no dozen type" to false
put 1 in record"dozen frequency"data index
loop until record"dozen frequency"data index > record"dozen frequency"data count
    begin
    if record"dozen frequency"data = record"temp"data
        begin
        add 1 in record"alone"data
        end
    add 1 in record"dozen frequency"data index
    end
If record"alone"data > 1
    begin
    set flag "no dozen type" to true
    end
end

method "update line frequencies"
begin
put 1 in record"number types"layout index
loop until record"number types"layout = record"last number"layout
    begin
    add 1 in record"number types"layout index
    end
put 100% of record"number types"layout index in record"line number"data index
put 100% of record"line number"data in record"line frequency"data index
add 1 to record"line frequency"data
end

method "select 'hottest' line type"
begin
// select "hottest" line type
put 1 in record"line frequency"data index
put 0 in record"temp"data
loop until record"line frequency"data index > record"line frequency"data count
    begin
    if record"line frequency"data > record"temp"data
        begin
        put 100% of record"line frequency"data in record"temp"data
        put 100% of record"line frequency"data index in record"line types"layout index
        copy record"line types"layout in record "line" layout
        end
    add 1 in record"line frequency"data index
    end
// check if "hottest" line type is the only coldest one
call "check for lonely line type"
end

method "select 'coldest' line type"
begin
// select "coldest" line type
put 1 in record"line frequency"data index
put 999999 in record"temp"data
loop until record"line frequency"data index > record"line frequency"data count
    begin
    if record"line frequency"data < record"temp"data
        begin
        put 100% of record"line frequency"data in record"temp"data
        put 100% of record"line frequency"data index in record"line types"layout index
        copy record"line types"layout in record "line" layout
        end
    add 1 in record"line frequency"data index
    end
// check if "coldest" line type is the only hottest one
call "check for lonely line type"
end

method "check for lonely line type"
begin
put 0 in record"alone"data
set flag "no line type" to false
put 1 in record"line frequency"data index
loop until record"line frequency"data index > record"line frequency"data count
    begin
    if record"line frequency"data = record"temp"data
        begin
        add 1 in record"alone"data
        end
    add 1 in record"line frequency"data index
    end
If record"alone"data > 1
    begin
    set flag "no line type" to true
    end
end

method "update corner frequencies"
begin
put 1 in record"corner frequency"data index
loop until record"corner frequency"data index > record"corner frequency"data count
    begin
    put 100% of record"corner frequency"data index in record"c1"data index
    if record"c1"data = record"last number decimal"data
        begin
        add 1 to record"corner frequency"data
        end
    put 100% of record"corner frequency"data index in record"c2"data index
    if record"c2"data = record"last number decimal"data
        begin
        add 1 to record"corner frequency"data
        end
    put 100% of record"corner frequency"data index in record"c3"data index
    if record"c3"data = record"last number decimal"data
        begin
        add 1 to record"corner frequency"data
        end
    put 100% of record"corner frequency"data index in record"c4"data index
    if record"c4"data = record"last number decimal"data
        begin
        add 1 to record"corner frequency"data
        end
    add 1 in record"corner frequency"data index
    end
end

method "select 'hottest' corner type"
begin
// select "hottest" corner type
put 1 in record"corner frequency"data index
put 0 in record"temp"data
loop until record"corner frequency"data index > record"corner frequency"data count
    begin
    if record"corner frequency"data > record"temp"data
        begin
        put 100% of record"corner frequency"data in record"temp"data
        put 100% of record"corner frequency"data index in record"corner types"layout index
        copy record"corner types"layout in record "corner" layout
        end
    add 1 in record"corner frequency"data index
    end
// check if "hottest" corner type is the only coldest one
call "check for lonely corner type"
end

method "select 'coldest' corner type"
begin
// select "coldest" corner type
put 1 in record"corner frequency"data index
put 999999 in record"temp"data
loop until record"corner frequency"data index > record"corner frequency"data count
    begin
    if record"corner frequency"data < record"temp"data
        begin
        put 100% of record"corner frequency"data in record"temp"data
        put 100% of record"corner frequency"data index in record"corner types"layout index
        copy record"corner types"layout in record "corner" layout
        end
    add 1 in record"corner frequency"data index
    end
// check if "coldest" corner type is the only hottest one
call "check for lonely corner type"
end

method "check for lonely corner type"
begin
put 0 in record"alone"data
set flag "no corner type" to false
put 1 in record"corner frequency"data index
loop until record"corner frequency"data index > record"corner frequency"data count
    begin
    if record"corner frequency"data = record"temp"data
        begin
        add 1 in record"alone"data
        end
    add 1 in record"corner frequency"data index
    end
If record"alone"data > 1
    begin
    set flag "no corner type" to true
    end
end

method "update street frequencies"
begin
put 1 in record"street types"layout index
loop until record"street types"layout = record"last street"layout
    begin
    add 1 in record"street types"layout index
    end
put 100% of record"street types"layout index in record"street frequency"data index
add 1 to record"street frequency"data
end

method "select 'hottest' street type"
begin
// select "hottest" street type
put 1 in record"street frequency"data index
put 0 in record"temp"data
loop until record"street frequency"data index > record"street frequency"data count
    begin
    if record"street frequency"data > record"temp"data
        begin
        put 100% of record"street frequency"data in record"temp"data
        put 100% of record"street frequency"data index in record"street types"layout index
        copy record"street types"layout in record "street" layout
        end
    add 1 in record"street frequency"data index
    end
// check if "hottest" street type is the only coldest one
call "check for lonely street type"
end

method "select 'coldest' street type"
begin
// select "coldest" street type
put 1 in record"street frequency"data index
put 999999 in record"temp"data
loop until record"street frequency"data index > record"street frequency"data count
    begin
    if record"street frequency"data < record"temp"data
        begin
        put 100% of record"street frequency"data in record"temp"data
        put 100% of record"street frequency"data index in record"street types"layout index
        copy record"street types"layout in record "street" layout
        end
    add 1 in record"street frequency"data index
    end
// check if "coldest" street type is the only hottest one
call "check for lonely street type"
end

method "check for lonely street type"
begin
put 0 in record"alone"data
set flag "no street type" to false
put 1 in record"street frequency"data index
loop until record"street frequency"data index > record"street frequency"data count
    begin
    if record"street frequency"data = record"temp"data
        begin
        add 1 in record"alone"data
        end
    add 1 in record"street frequency"data index
    end
If record"alone"data > 1
    begin
    set flag "no street type" to true
    end
end

method "update split frequencies"
begin
put 1 in record"split frequency"data index
loop until record"split frequency"data index > record"split frequency"data count
    begin
    put 100% of record"split frequency"data index in record"s1"data index
    if record"s1"data = record"last number decimal"data
        begin
        add 1 to record"split frequency"data
        end
    put 100% of record"split frequency"data index in record"s2"data index
    if record"s2"data = record"last number decimal"data
        begin
        add 1 to record"split frequency"data
        end
    add 1 in record"split frequency"data index
    end
end

method "select 'hottest' split type"
begin
// select "hottest" split type
put 1 in record"split frequency"data index
put 0 in record"temp"data
loop until record"split frequency"data index > record"split frequency"data count
    begin
    if record"split frequency"data > record"temp"data
        begin
        put 100% of record"split frequency"data in record"temp"data
        put 100% of record"split frequency"data index in record"split types"layout index
        copy record"split types"layout in record "split" layout
        end
    add 1 in record"split frequency"data index
    end
// check if "hottest" split type is the only coldest one
call "check for lonely split type"
end

method "select 'coldest' split type"
begin
// select "coldest" split type
put 1 in record"split frequency"data index
put 999999 in record"temp"data
loop until record"split frequency"data index > record"split frequency"data count
    begin
    if record"split frequency"data < record"temp"data
        begin
        put 100% of record"split frequency"data in record"temp"data
        put 100% of record"split frequency"data index in record"split types"layout index
        copy record"split types"layout in record "split" layout
        end
    add 1 in record"split frequency"data index
    end
// check if "coldest" split type is the only hottest one
call "check for lonely split type"
end

method "check for lonely split type"
begin
put 0 in record"alone"data
set flag "no split type" to false
put 1 in record"split frequency"data index
loop until record"split frequency"data index > record"split frequency"data count
    begin
    if record"split frequency"data = record"temp"data
        begin
        add 1 in record"alone"data
        end
    add 1 in record"split frequency"data index
    end
If record"alone"data > 1
    begin
    set flag "no split type" to true
    end
end