system "The Two Dozens v1"
{
*************************************
*         System by toby            *
*        on the VIP Lounge          *
*************************************
         Rx-ed by Sp1N-D1zZy
-------------------------------------
           00-c0mpatible
-------------------------------------
The first part is only virtual game so you do not place any bet
until a condition happens.

1)you play on 2 dozens
2)if 2 different dozens come you bet on the ones that came
3)if a dozen repeats you play on the other 2.
4)if zero hits you wait for 2 spins to continue.
5)you apply the progression 1 2 3 4 5....
6)you raise your bets if you are not +1 no matter you hit or missed.
7)if you get +1 you reset the BR

Up to that you just see the results
You wait for a -120 to start betting.

part 2
As soon as you face -120 without betting you place 1 unit on each dozen
as described in 1) to 7). You chase for +1, you do not try to make for the -120

when you got +1 you go to virtual game again.

-------------------------------------
}
method "main"
begin
while starting new session
    begin
    call "Init"
    exit
    end
call "Track"
end

method "Bet"
begin
if flag "Virtual Mode" true
    begin
    track last dozen for 1 spins record"Last Dozen"layout
    if record"Last Dozen"layout list pattern match record"1st Dozen"layout
    or record"Last Dozen"layout list pattern match record"2nd Dozen"layout
        begin
        add 1 record"Progression"data
        add 100% record"Progression"data record"Virtual Bank"data
        end else begin
        add 1 record"Progression"data
        put 100% record"Progression"data record"Temp"data
        multiply 2 record"Temp"data
        subtract 100% record"Temp"data record"Virtual Bank"data
        end
    if record"Virtual Bank"data > 0
        begin
        put 0 record"Virtual Bank"data
        end
    if record"Virtual Bank"data <= -120
        begin
        clear record"Virtual Bank"data
        call "Init"
        set flag "Virtual Mode" false
        end
    end
end

method "Track"
begin
add 1 record"Count"data
track last number for 1 spins record"Last Number"layout
if record"Last Number"layout = number 0
    begin
    put 0 record"Count"data
    end
if record"Count"data > 2
    begin
    call "Bet"
    end
track last dozen for 2 spins record"Last 2 Dozens"layout
put 1 record"Last 2 Dozens"layout index
copy record"Last 2 Dozens"layout record"1st Dozen"layout
put 2 record"Last 2 Dozens"layout index
copy record"Last 2 Dozens"layout record"2nd Dozen"layout
if record"1st Dozen"layout list pattern match record"2nd Dozen"layout
    begin
    if list [1st Dozen] pattern match record"1st Dozen"layout
        begin
        copy list [2nd Dozen] record"1st Dozen"layout
        copy list [3rd Dozen] record"2nd Dozen"layout
        end else begin
            if list [2nd Dozen] pattern match record"1st Dozen"layout
            begin
            copy list [1st Dozen] record"1st Dozen"layout
            copy list [3rd Dozen] record"2nd Dozen"layout
            end else begin
                if list [3rd Dozen] pattern match record"1st Dozen"layout
                begin
                copy list [1st Dozen] record"1st Dozen"layout
                copy list [2nd Dozen] record"2nd Dozen"layout
                end
            end
        end
    end
if flag "Virtual Mode" false
    begin
    add 100% net record"Profit"data
    if record"Profit"data > 0
        begin
        call "Init"
        exit
        end
    add 1 record"Progression" data
    put 100% record"Progression"data record"1st Dozen"layout
    put 100% record"Progression"data record"2nd Dozen"layout
    end
end

method "Init"
begin
put 0 record"Progression"data
set flag "Virtual Mode" true
put 0 record"Temp"data
put 0 record"Virtual Bank"data
put 0 record"Profit"data
end