system "RedHunters dozens II v1"
{
*************************************
*      System by RedHunter          *
*       on the VIP Lounge           *
*************************************
        Rx-ed by St0rm0r

Betting on the Dozens.
Use the last two (different) dozens to show.
On a loss, bet the same amount as last time.
On a win, increase the next bets on the two dozens 1 unit each.
Until new high
IE:
Dozen
1
1
1
2
now bet dozens 1 and 2 --->1 unit.
3 Lost -2 units Next bet is 1 unit on Dozen 2 and 1 unit on Dozen 3.
3 win +1 unit total loss -1. Next bet is 2 units on dozen 2 and Dozen 3.
3 Win +1 Total win. Now reset to 1 unit on 2 and one unit on 3.

Skip until win after 2 consecutive losses.
}
method "main"
begin
// section 1: do this once
while starting new session
    begin
    call "init"
    exit
    end

// section 2: do the tracking
if record"last dozen"layout = record"dozenA"layout or
record"last dozen"layout = record"dozenB"layout
    begin
    set flag "wait" false
    end

track last number for 1 time record"last#"layout
if record"last#"layout not = number 0 and record"last#"layout not = number 00
    begin
    track last dozen for 1 time record"last dozen"layout
    if record"last dozen"layout not = record"dozenA"layout and
    record"last dozen"layout not = record"dozenB"layout
        begin
        copy record"dozenB"layout in record"dozenA"layout
        copy record"last dozen"layout in record"dozenB"layout
        end
        else
        begin
        if record"last dozen"layout = record"dozenA"layout
            begin
            copy record"dozenB"layout in record"dozenA"layout
            copy record"last dozen"layout in record"dozenB"layout
            end
        end
    end

// section 3: act on a loss
if net < 0
    begin
    add 1 record"#losses"data
    if record"#losses"data = 2
        begin
        set flag "wait" true
        end
    end

// section 4:act on a win
if net > 0
    begin
    put 0 record"#losses"data
    add 1 record"bet"data
    if bankroll > record"new high"data
        begin
        call "reset"
        end
    end

// section 5: what to do when not qualified
if flag "qualified" false
    begin
    if record"dozenA"layout not = red and
    record"dozenB"layout not = red
        begin
        set flag "qualified" true
        end
    end

// section 6: what to do when qualified
if flag "qualified" true
    begin
    // bet
    if flag "wait" false
        begin
        put 100% record"bet"data on record"dozenA"layout
        put 100% record"bet"data on record"dozenB"layout
        end
    end

end

// subroutines
method "init"
begin
copy red record"dozenA"layout
copy red record"dozenB"layout
call "reset"
end

method "reset"
begin
set flag "qualified" false
put 100% bankroll record"new high"data
put 1 record"bet"data
put 0 record"#losses"data
set flag "wait" false
end