system "Il Palio"
{
Sistema: il Palio
Creato da: Lonerider
Xtremizzato da: LaRoulette.it
 
 Il sistema prevede la suddivisione della ruota in un settore giocabile con 9 cavalli.
 Attendere che esca un numero del settore e poi giocarlo con una progressione in vincita
 di tre termini.
 Ad ogni colpo vinto attendere l'interruzione della serie prima di fare un nuovo attacco
 Stopwin:  5 attacchi  vinti.
 stoploss:  <-180
 
 spiegazione del sistema su: www.laroulette.it
 
}
method "main"
begin
    While Starting new Session
    begin
        //Inizializza variabili creando una lista di cavalli ed una dei numeri che formano il settore del palio
        copy list [Split(5-6), Split(8-9),Split(10-11),Split(13-14),Split(16-17),Split(23-24),Split(27-30),Split(31-34),Split(33-36)] to Record "Cavalli" layout
        copy list [5,6,8,9,10,11,13,14,16,17,23,24,27,30,31,33,34,36] to Record "Palio" layout
        set Flag "Gioca" to false
        Put 0 to Record "Uguale" Data
        Put 0 to Record "Serie" Data
    end
    
    While On each Spin
    begin
        if Record "Vinte" Data >=5 //controlla stopwin
        or Bankroll <-180          // controlla stoploss
        begin
            exit
        end
        Copy last number to Record "Uscito" layout // memorizza l'ultimo numero nel record 'uscito'
        Call "Verifica";
        if Record "Uguale" Data >= 1 // se è uscito un numero del Palio allora punta
        begin
             Call "Punta";
        end

    end
end

method "Verifica"
begin
    //controlla se il numero uscito è del palio e setta il flag uguale
    Put 1 Record "Palio" layout index //imposta ad uno il contatore dell'indice
    set Flag "Gioca" to false // mette come default che non è in gioco
    Loop until record "Palio" layout index > record "Palio" layout count
    begin  // confronta il numero uscito con tutti i numeri del palio
        If Record "Palio" layout = Record "Uscito" layout //se lo trova allora
        begin
            set Flag "Gioca" to true // segnala che è in gioco
        end
       Add 1 to Record "Palio" layout index //incrementa di 1 il contatore
    end
    If Flag "Gioca" is true  // se è in gioco
    and flag "Attendi" is false //e se non è la serie vincente che continua
    begin
        add 1 to record "Uguale" data //incrementa il contatore parziale del palio
    end
    If Flag "Gioca" is false //se non è uscito un numero del palio
    begin
            set flag "Attendi" false //segnala che la serie vincente si è interrotta
            Put 0 to record "Uguale" data //azzera il contatore parziale dl palio
    end

end

method "Punta"
begin
        If Win units = 0 and Record "Uguale" data=1 then //controlla che sia la prima puntata
        begin
            Put 1 unit on Record "Cavalli" layout list  // mette i pezzi su ognuno dei cavalli
        end
        If Win units = 18 then  //Ad ogni colpo vinto effettua il paroli
        begin
            Put 2 unit on Record "Cavalli" layout list
        end
        If Win units = 36 then//Ad ogni colpo vinto effettua il paroli
        begin
            Put 4 unit on Record "Cavalli" layout list
        end
        If Win units = 72 then //Se arriva vincente all'ultimo termine riazzera il conteggio
        begin
            add 1 record "Vinte" Data //incrementa il contatore delle partite vinte
            Set flag "Attendi" true
        end
end