Streets - Minimum Interval

Contenuto del file

system "Streets - Minimum Interval"

{
Play a progression on the street with the highest minimum interval
until all streets have repeated (values are all "1")
}

Method "Main"
begin
  While Starting a New Session
    begin
      Call "Setup"
    end
    Call "Process"
    Call "Bet"
end

Method "Process"
 begin
   Add 1 to record "Spin Counter" data
   Set Flag "All Equal One" True
   Calculate Min Interval of Street(1-3) to record "MI Value" data
   Put 1 on record "Layout Pointer" data
   put 1 on record "Street List" layout index
   Loop until record "Street List" layout index > record "Street List" layout count
   begin
     Calculate Min Interval of record "Street List" layout to record "MI Check" data
     if record "MI Check" data > record "MI Value" data
        begin
            put 100% record "MI Check" data on record "MI Value" data
            put 100% record "Street List" Layout index on record "Layout Pointer" data
        end
      if record "MI Check" data > 1
         begin
           Set Flag "All Equal One" False
         end
      Add 1 to record "Street List" layout index
   end
   if Flag "All Equal One" True and record "Spin Counter" data > 5
   begin
     Display "All Streets have repeated at least once, End of Session"
     Stop Session
   end
   put 100% record "Layout Pointer" data on record "Street List" layout index
   duplicate record "Street List" record "Target Street"
end

Method "Bet"
begin
  if any inside bet won each
     begin
       Put 1 on record "Progression" data index
     end
  else
    begin
      Add 1 to record "Progression" data index
      if record "Progression" data index > record "Progression" data count
         begin
            Put 1 on record "Progression" data index
         end
    end

    put 100% record "Progression" data on record "Target Street" layout
end

Method "Setup"
begin
  Put 0 on record "Spin Counter" data
  Set Flag "All Equal One" True
  Put 0 on record "MI Check" data
  Put 0 on record "MI Value" data
  Put 0 on record "Layout Pointer" data
  Copy List [Street(1-3), Street(4-6), Street(7-9), Street(10-12), Street(13-15), Street(16-18),
  Street(19-21), Street(22-24), Street(25-27), Street(28-30), Street(31-33), Street(34-36)] record "Street List" layout
  Set List[1, 1, 1, 1, 1, 1, 1, 1, 1, 2, 2, 2, 2, 2, 2, 3, 3, 3, 3, 4, 4, 4,
     5, 5, 6, 6, 7, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 18, 20, 21, 23, 25, 28,
     30, 33,36, 39, 43, 47, 51, 56, 61, 66, 72, 79, 86, 94, 102, 112, 122] on record "Progression" data
  Put 0 on record "Progression" data index
end